| 1 | # boost.m4: Locate Boost headers and libraries for autoconf-based projects.
|
|---|
| 2 | # Copyright (C) 2007, 2008, 2009, 2010, 2011 Benoit Sigoure <tsuna@lrde.epita.fr>
|
|---|
| 3 | #
|
|---|
| 4 | # This program is free software: you can redistribute it and/or modify
|
|---|
| 5 | # it under the terms of the GNU General Public License as published by
|
|---|
| 6 | # the Free Software Foundation, either version 3 of the License, or
|
|---|
| 7 | # (at your option) any later version.
|
|---|
| 8 | #
|
|---|
| 9 | # Additional permission under section 7 of the GNU General Public
|
|---|
| 10 | # License, version 3 ("GPLv3"):
|
|---|
| 11 | #
|
|---|
| 12 | # If you convey this file as part of a work that contains a
|
|---|
| 13 | # configuration script generated by Autoconf, you may do so under
|
|---|
| 14 | # terms of your choice.
|
|---|
| 15 | #
|
|---|
| 16 | # This program is distributed in the hope that it will be useful,
|
|---|
| 17 | # but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|---|
| 18 | # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|---|
| 19 | # GNU General Public License for more details.
|
|---|
| 20 | #
|
|---|
| 21 | # You should have received a copy of the GNU General Public License
|
|---|
| 22 | # along with this program. If not, see <http://www.gnu.org/licenses/>.
|
|---|
| 23 |
|
|---|
| 24 | m4_define([_BOOST_SERIAL], [m4_translit([
|
|---|
| 25 | # serial 15
|
|---|
| 26 | ], [#
|
|---|
| 27 | ], [])])
|
|---|
| 28 |
|
|---|
| 29 | # Original sources can be found at http://github.com/tsuna/boost.m4
|
|---|
| 30 | # You can fetch the latest version of the script by doing:
|
|---|
| 31 | # wget http://github.com/tsuna/boost.m4/raw/master/build-aux/boost.m4
|
|---|
| 32 |
|
|---|
| 33 | # ------ #
|
|---|
| 34 | # README #
|
|---|
| 35 | # ------ #
|
|---|
| 36 |
|
|---|
| 37 | # This file provides several macros to use the various Boost libraries.
|
|---|
| 38 | # The first macro is BOOST_REQUIRE. It will simply check if it's possible to
|
|---|
| 39 | # find the Boost headers of a given (optional) minimum version and it will
|
|---|
| 40 | # define BOOST_CPPFLAGS accordingly. It will add an option --with-boost to
|
|---|
| 41 | # your configure so that users can specify non standard locations.
|
|---|
| 42 | # If the user's environment contains BOOST_ROOT and --with-boost was not
|
|---|
| 43 | # specified, --with-boost=$BOOST_ROOT is implicitly used.
|
|---|
| 44 | # For more README and documentation, go to http://github.com/tsuna/boost.m4
|
|---|
| 45 | # Note: THESE MACROS ASSUME THAT YOU USE LIBTOOL. If you don't, don't worry,
|
|---|
| 46 | # simply read the README, it will show you what to do step by step.
|
|---|
| 47 |
|
|---|
| 48 | m4_pattern_forbid([^_?(BOOST|Boost)_])
|
|---|
| 49 |
|
|---|
| 50 |
|
|---|
| 51 | # _BOOST_SED_CPP(SED-PROGRAM, PROGRAM,
|
|---|
| 52 | # [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
|
|---|
| 53 | # --------------------------------------------------------
|
|---|
| 54 | # Same as AC_EGREP_CPP, but leave the result in conftest.i.
|
|---|
| 55 | #
|
|---|
| 56 | # SED-PROGRAM is *not* overquoted, as in AC_EGREP_CPP. It is expanded
|
|---|
| 57 | # in double-quotes, so escape your double quotes.
|
|---|
| 58 | #
|
|---|
| 59 | # It could be useful to turn this into a macro which extracts the
|
|---|
| 60 | # value of any macro.
|
|---|
| 61 | m4_define([_BOOST_SED_CPP],
|
|---|
| 62 | [AC_LANG_PREPROC_REQUIRE()dnl
|
|---|
| 63 | AC_REQUIRE([AC_PROG_SED])dnl
|
|---|
| 64 | AC_LANG_CONFTEST([AC_LANG_SOURCE([[$2]])])
|
|---|
| 65 | AS_IF([dnl eval is necessary to expand ac_cpp.
|
|---|
| 66 | dnl Ultrix and Pyramid sh refuse to redirect output of eval, so use subshell.
|
|---|
| 67 | dnl Beware of Windows end-of-lines, for instance if we are running
|
|---|
| 68 | dnl some Windows programs under Wine. In that case, boost/version.hpp
|
|---|
| 69 | dnl is certainly using "\r\n", but the regular Unix shell will only
|
|---|
| 70 | dnl strip `\n' with backquotes, not the `\r'. This results in
|
|---|
| 71 | dnl boost_cv_lib_version='1_37\r' for instance, which breaks
|
|---|
| 72 | dnl everything else.
|
|---|
| 73 | dnl Cannot use 'dnl' after [$4] because a trailing dnl may break AC_CACHE_CHECK
|
|---|
| 74 | (eval "$ac_cpp conftest.$ac_ext") 2>&AS_MESSAGE_LOG_FD |
|
|---|
| 75 | tr -d '\r' |
|
|---|
| 76 | $SED -n -e "$1" >conftest.i 2>&1],
|
|---|
| 77 | [$3],
|
|---|
| 78 | [$4])
|
|---|
| 79 | rm -rf conftest*
|
|---|
| 80 | ])# AC_EGREP_CPP
|
|---|
| 81 |
|
|---|
| 82 |
|
|---|
| 83 |
|
|---|
| 84 | # BOOST_REQUIRE([VERSION], [ACTION-IF-NOT-FOUND])
|
|---|
| 85 | # -----------------------------------------------
|
|---|
| 86 | # Look for Boost. If version is given, it must either be a literal of the form
|
|---|
| 87 | # "X.Y.Z" where X, Y and Z are integers (the ".Z" part being optional) or a
|
|---|
| 88 | # variable "$var".
|
|---|
| 89 | # Defines the value BOOST_CPPFLAGS. This macro only checks for headers with
|
|---|
| 90 | # the required version, it does not check for any of the Boost libraries.
|
|---|
| 91 | # On # success, defines HAVE_BOOST. On failure, calls the optional
|
|---|
| 92 | # ACTION-IF-NOT-FOUND action if one was supplied.
|
|---|
| 93 | # Otherwise aborts with an error message.
|
|---|
| 94 | AC_DEFUN([BOOST_REQUIRE],
|
|---|
| 95 | [AC_REQUIRE([AC_PROG_CXX])dnl
|
|---|
| 96 | AC_REQUIRE([AC_PROG_GREP])dnl
|
|---|
| 97 | echo "$as_me: this is boost.m4[]_BOOST_SERIAL" >&AS_MESSAGE_LOG_FD
|
|---|
| 98 | boost_save_IFS=$IFS
|
|---|
| 99 | boost_version_req=$1
|
|---|
| 100 | IFS=.
|
|---|
| 101 | set x $boost_version_req 0 0 0
|
|---|
| 102 | IFS=$boost_save_IFS
|
|---|
| 103 | shift
|
|---|
| 104 | boost_version_req=`expr "$[1]" '*' 100000 + "$[2]" '*' 100 + "$[3]"`
|
|---|
| 105 | boost_version_req_string=$[1].$[2].$[3]
|
|---|
| 106 | AC_ARG_WITH([boost],
|
|---|
| 107 | [AS_HELP_STRING([--with-boost=DIR],
|
|---|
| 108 | [prefix of Boost $1 @<:@guess@:>@])])dnl
|
|---|
| 109 | AC_ARG_VAR([BOOST_ROOT],[Location of Boost installation])dnl
|
|---|
| 110 | # If BOOST_ROOT is set and the user has not provided a value to
|
|---|
| 111 | # --with-boost, then treat BOOST_ROOT as if it the user supplied it.
|
|---|
| 112 | if test x"$BOOST_ROOT" != x; then
|
|---|
| 113 | if test x"$with_boost" = x; then
|
|---|
| 114 | AC_MSG_NOTICE([Detected BOOST_ROOT; continuing with --with-boost=$BOOST_ROOT])
|
|---|
| 115 | with_boost=$BOOST_ROOT
|
|---|
| 116 | else
|
|---|
| 117 | AC_MSG_NOTICE([Detected BOOST_ROOT=$BOOST_ROOT, but overridden by --with-boost=$with_boost])
|
|---|
| 118 | fi
|
|---|
| 119 | fi
|
|---|
| 120 | AC_SUBST([DISTCHECK_CONFIGURE_FLAGS],
|
|---|
| 121 | ["$DISTCHECK_CONFIGURE_FLAGS '--with-boost=$with_boost'"])dnl
|
|---|
| 122 | boost_save_CPPFLAGS=$CPPFLAGS
|
|---|
| 123 | AC_CACHE_CHECK([for Boost headers version >= $boost_version_req_string],
|
|---|
| 124 | [boost_cv_inc_path],
|
|---|
| 125 | [boost_cv_inc_path=no
|
|---|
| 126 | AC_LANG_PUSH([C++])dnl
|
|---|
| 127 | m4_pattern_allow([^BOOST_VERSION$])dnl
|
|---|
| 128 | AC_LANG_CONFTEST([AC_LANG_PROGRAM([[#include <boost/version.hpp>
|
|---|
| 129 | #if !defined BOOST_VERSION
|
|---|
| 130 | # error BOOST_VERSION is not defined
|
|---|
| 131 | #elif BOOST_VERSION < $boost_version_req
|
|---|
| 132 | # error Boost headers version < $boost_version_req
|
|---|
| 133 | #endif
|
|---|
| 134 | ]])])
|
|---|
| 135 | # If the user provided a value to --with-boost, use it and only it.
|
|---|
| 136 | case $with_boost in #(
|
|---|
| 137 | ''|yes) set x '' /opt/local/include /usr/local/include /opt/include \
|
|---|
| 138 | /usr/include C:/Boost/include;; #(
|
|---|
| 139 | *) set x "$with_boost/include" "$with_boost";;
|
|---|
| 140 | esac
|
|---|
| 141 | shift
|
|---|
| 142 | for boost_dir
|
|---|
| 143 | do
|
|---|
| 144 | # Without --layout=system, Boost (or at least some versions) installs
|
|---|
| 145 | # itself in <prefix>/include/boost-<version>. This inner loop helps to
|
|---|
| 146 | # find headers in such directories.
|
|---|
| 147 | #
|
|---|
| 148 | # Any ${boost_dir}/boost-x_xx directories are searched in reverse version
|
|---|
| 149 | # order followed by ${boost_dir}. The final '.' is a sentinel for
|
|---|
| 150 | # searching $boost_dir" itself. Entries are whitespace separated.
|
|---|
| 151 | #
|
|---|
| 152 | # I didn't indent this loop on purpose (to avoid over-indented code)
|
|---|
| 153 | boost_layout_system_search_list=`cd "$boost_dir" 2>/dev/null \
|
|---|
| 154 | && ls -1 | "${GREP}" '^boost-' | sort -rn -t- -k2 \
|
|---|
| 155 | && echo .`
|
|---|
| 156 | for boost_inc in $boost_layout_system_search_list
|
|---|
| 157 | do
|
|---|
| 158 | if test x"$boost_inc" != x.; then
|
|---|
| 159 | boost_inc="$boost_dir/$boost_inc"
|
|---|
| 160 | else
|
|---|
| 161 | boost_inc="$boost_dir" # Uses sentinel in boost_layout_system_search_list
|
|---|
| 162 | fi
|
|---|
| 163 | if test x"$boost_inc" != x; then
|
|---|
| 164 | # We are going to check whether the version of Boost installed
|
|---|
| 165 | # in $boost_inc is usable by running a compilation that
|
|---|
| 166 | # #includes it. But if we pass a -I/some/path in which Boost
|
|---|
| 167 | # is not installed, the compiler will just skip this -I and
|
|---|
| 168 | # use other locations (either from CPPFLAGS, or from its list
|
|---|
| 169 | # of system include directories). As a result we would use
|
|---|
| 170 | # header installed on the machine instead of the /some/path
|
|---|
| 171 | # specified by the user. So in that precise case (trying
|
|---|
| 172 | # $boost_inc), make sure the version.hpp exists.
|
|---|
| 173 | #
|
|---|
| 174 | # Use test -e as there can be symlinks.
|
|---|
| 175 | test -e "$boost_inc/boost/version.hpp" || continue
|
|---|
| 176 | CPPFLAGS="$CPPFLAGS -I$boost_inc"
|
|---|
| 177 | fi
|
|---|
| 178 | AC_COMPILE_IFELSE([], [boost_cv_inc_path=yes], [boost_cv_version=no])
|
|---|
| 179 | if test x"$boost_cv_inc_path" = xyes; then
|
|---|
| 180 | if test x"$boost_inc" != x; then
|
|---|
| 181 | boost_cv_inc_path=$boost_inc
|
|---|
| 182 | fi
|
|---|
| 183 | break 2
|
|---|
| 184 | fi
|
|---|
| 185 | done
|
|---|
| 186 | done
|
|---|
| 187 | AC_LANG_POP([C++])dnl
|
|---|
| 188 | ])
|
|---|
| 189 | case $boost_cv_inc_path in #(
|
|---|
| 190 | no)
|
|---|
| 191 | boost_errmsg="cannot find Boost headers version >= $boost_version_req_string"
|
|---|
| 192 | m4_if([$2], [], [AC_MSG_ERROR([$boost_errmsg])],
|
|---|
| 193 | [AC_MSG_NOTICE([$boost_errmsg])])
|
|---|
| 194 | $2
|
|---|
| 195 | ;;#(
|
|---|
| 196 | yes)
|
|---|
| 197 | BOOST_CPPFLAGS=
|
|---|
| 198 | ;;#(
|
|---|
| 199 | *)
|
|---|
| 200 | AC_SUBST([BOOST_CPPFLAGS], ["-I$boost_cv_inc_path"])dnl
|
|---|
| 201 | ;;
|
|---|
| 202 | esac
|
|---|
| 203 | if test x"$boost_cv_inc_path" != xno; then
|
|---|
| 204 | AC_DEFINE([HAVE_BOOST], [1],
|
|---|
| 205 | [Defined if the requested minimum BOOST version is satisfied])
|
|---|
| 206 | AC_CACHE_CHECK([for Boost's header version],
|
|---|
| 207 | [boost_cv_lib_version],
|
|---|
| 208 | [m4_pattern_allow([^BOOST_LIB_VERSION$])dnl
|
|---|
| 209 | _BOOST_SED_CPP([/^boost-lib-version = /{s///;s/\"//g;p;q;}],
|
|---|
| 210 | [#include <boost/version.hpp>
|
|---|
| 211 | boost-lib-version = BOOST_LIB_VERSION],
|
|---|
| 212 | [boost_cv_lib_version=`cat conftest.i`])])
|
|---|
| 213 | # e.g. "134" for 1_34_1 or "135" for 1_35
|
|---|
| 214 | boost_major_version=`echo "$boost_cv_lib_version" | sed 's/_//;s/_.*//'`
|
|---|
| 215 | case $boost_major_version in #(
|
|---|
| 216 | '' | *[[!0-9]]*)
|
|---|
| 217 | AC_MSG_ERROR([invalid value: boost_major_version=$boost_major_version])
|
|---|
| 218 | ;;
|
|---|
| 219 | esac
|
|---|
| 220 | fi
|
|---|
| 221 | CPPFLAGS=$boost_save_CPPFLAGS
|
|---|
| 222 | ])# BOOST_REQUIRE
|
|---|
| 223 |
|
|---|
| 224 | # BOOST_STATIC()
|
|---|
| 225 | # --------------
|
|---|
| 226 | # Add the "--enable-static-boost" configure argument. If this argument is given
|
|---|
| 227 | # on the command line, static versions of the libraries will be looked up.
|
|---|
| 228 | AC_DEFUN([BOOST_STATIC],
|
|---|
| 229 | [AC_ARG_ENABLE([static-boost],
|
|---|
| 230 | [AC_HELP_STRING([--enable-static-boost],
|
|---|
| 231 | [Prefer the static boost libraries over the shared ones [no]])],
|
|---|
| 232 | [enable_static_boost=yes],
|
|---|
| 233 | [enable_static_boost=no])])# BOOST_STATIC
|
|---|
| 234 |
|
|---|
| 235 | # BOOST_FIND_HEADER([HEADER-NAME], [ACTION-IF-NOT-FOUND], [ACTION-IF-FOUND])
|
|---|
| 236 | # --------------------------------------------------------------------------
|
|---|
| 237 | # Wrapper around AC_CHECK_HEADER for Boost headers. Useful to check for
|
|---|
| 238 | # some parts of the Boost library which are only made of headers and don't
|
|---|
| 239 | # require linking (such as Boost.Foreach).
|
|---|
| 240 | #
|
|---|
| 241 | # Default ACTION-IF-NOT-FOUND: Fail with a fatal error unless Boost couldn't be
|
|---|
| 242 | # found in the first place, in which case by default a notice is issued to the
|
|---|
| 243 | # user. Presumably if we haven't died already it's because it's OK to not have
|
|---|
| 244 | # Boost, which is why only a notice is issued instead of a hard error.
|
|---|
| 245 | #
|
|---|
| 246 | # Default ACTION-IF-FOUND: define the preprocessor symbol HAVE_<HEADER-NAME> in
|
|---|
| 247 | # case of success # (where HEADER-NAME is written LIKE_THIS, e.g.,
|
|---|
| 248 | # HAVE_BOOST_FOREACH_HPP).
|
|---|
| 249 | AC_DEFUN([BOOST_FIND_HEADER],
|
|---|
| 250 | [AC_REQUIRE([BOOST_REQUIRE])dnl
|
|---|
| 251 | if test x"$boost_cv_inc_path" = xno; then
|
|---|
| 252 | m4_default([$2], [AC_MSG_NOTICE([Boost not available, not searching for $1])])
|
|---|
| 253 | else
|
|---|
| 254 | AC_LANG_PUSH([C++])dnl
|
|---|
| 255 | boost_save_CPPFLAGS=$CPPFLAGS
|
|---|
| 256 | CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
|
|---|
| 257 | AC_CHECK_HEADER([$1],
|
|---|
| 258 | [m4_default([$3], [AC_DEFINE(AS_TR_CPP([HAVE_$1]), [1],
|
|---|
| 259 | [Define to 1 if you have <$1>])])],
|
|---|
| 260 | [m4_default([$2], [AC_MSG_ERROR([cannot find $1])])])
|
|---|
| 261 | CPPFLAGS=$boost_save_CPPFLAGS
|
|---|
| 262 | AC_LANG_POP([C++])dnl
|
|---|
| 263 | fi
|
|---|
| 264 | ])# BOOST_FIND_HEADER
|
|---|
| 265 |
|
|---|
| 266 |
|
|---|
| 267 | # BOOST_FIND_LIB([LIB-NAME], [PREFERRED-RT-OPT], [HEADER-NAME], [CXX-TEST],
|
|---|
| 268 | # [CXX-PROLOGUE])
|
|---|
| 269 | # -------------------------------------------------------------------------
|
|---|
| 270 | # Look for the Boost library LIB-NAME (e.g., LIB-NAME = `thread', for
|
|---|
| 271 | # libboost_thread). Check that HEADER-NAME works and check that
|
|---|
| 272 | # libboost_LIB-NAME can link with the code CXX-TEST. The optional argument
|
|---|
| 273 | # CXX-PROLOGUE can be used to include some C++ code before the `main'
|
|---|
| 274 | # function.
|
|---|
| 275 | #
|
|---|
| 276 | # Invokes BOOST_FIND_HEADER([HEADER-NAME]) (see above).
|
|---|
| 277 | #
|
|---|
| 278 | # Boost libraries typically come compiled with several flavors (with different
|
|---|
| 279 | # runtime options) so PREFERRED-RT-OPT is the preferred suffix. A suffix is one
|
|---|
| 280 | # or more of the following letters: sgdpn (in that order). s = static
|
|---|
| 281 | # runtime, d = debug build, g = debug/diagnostic runtime, p = STLPort build,
|
|---|
| 282 | # n = (unsure) STLPort build without iostreams from STLPort (it looks like `n'
|
|---|
| 283 | # must always be used along with `p'). Additionally, PREFERRED-RT-OPT can
|
|---|
| 284 | # start with `mt-' to indicate that there is a preference for multi-thread
|
|---|
| 285 | # builds. Some sample values for PREFERRED-RT-OPT: (nothing), mt, d, mt-d, gdp
|
|---|
| 286 | # ... If you want to make sure you have a specific version of Boost
|
|---|
| 287 | # (eg, >= 1.33) you *must* invoke BOOST_REQUIRE before this macro.
|
|---|
| 288 | AC_DEFUN([BOOST_FIND_LIB],
|
|---|
| 289 | [AC_REQUIRE([BOOST_REQUIRE])dnl
|
|---|
| 290 | AC_REQUIRE([_BOOST_FIND_COMPILER_TAG])dnl
|
|---|
| 291 | AC_REQUIRE([BOOST_STATIC])dnl
|
|---|
| 292 | AC_REQUIRE([_BOOST_GUESS_WHETHER_TO_USE_MT])dnl
|
|---|
| 293 | if test x"$boost_cv_inc_path" = xno; then
|
|---|
| 294 | AC_MSG_NOTICE([Boost not available, not searching for the Boost $1 library])
|
|---|
| 295 | else
|
|---|
| 296 | dnl The else branch is huge and wasn't intended on purpose.
|
|---|
| 297 | AC_LANG_PUSH([C++])dnl
|
|---|
| 298 | AS_VAR_PUSHDEF([Boost_lib], [boost_cv_lib_$1])dnl
|
|---|
| 299 | AS_VAR_PUSHDEF([Boost_lib_LDFLAGS], [boost_cv_lib_$1_LDFLAGS])dnl
|
|---|
| 300 | AS_VAR_PUSHDEF([Boost_lib_LDPATH], [boost_cv_lib_$1_LDPATH])dnl
|
|---|
| 301 | AS_VAR_PUSHDEF([Boost_lib_LIBS], [boost_cv_lib_$1_LIBS])dnl
|
|---|
| 302 | BOOST_FIND_HEADER([$3])
|
|---|
| 303 | boost_save_CPPFLAGS=$CPPFLAGS
|
|---|
| 304 | CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
|
|---|
| 305 | # Now let's try to find the library. The algorithm is as follows: first look
|
|---|
| 306 | # for a given library name according to the user's PREFERRED-RT-OPT. For each
|
|---|
| 307 | # library name, we prefer to use the ones that carry the tag (toolset name).
|
|---|
| 308 | # Each library is searched through the various standard paths were Boost is
|
|---|
| 309 | # usually installed. If we can't find the standard variants, we try to
|
|---|
| 310 | # enforce -mt (for instance on MacOSX, libboost_threads.dylib doesn't exist
|
|---|
| 311 | # but there's -obviously- libboost_threads-mt.dylib).
|
|---|
| 312 | AC_CACHE_CHECK([for the Boost $1 library], [Boost_lib],
|
|---|
| 313 | [Boost_lib=no
|
|---|
| 314 | case "$2" in #(
|
|---|
| 315 | mt | mt-) boost_mt=-mt; boost_rtopt=;; #(
|
|---|
| 316 | mt* | mt-*) boost_mt=-mt; boost_rtopt=`expr "X$2" : 'Xmt-*\(.*\)'`;; #(
|
|---|
| 317 | *) boost_mt=; boost_rtopt=$2;;
|
|---|
| 318 | esac
|
|---|
| 319 | if test $enable_static_boost = yes; then
|
|---|
| 320 | boost_rtopt="s$boost_rtopt"
|
|---|
| 321 | fi
|
|---|
| 322 | # Find the proper debug variant depending on what we've been asked to find.
|
|---|
| 323 | case $boost_rtopt in #(
|
|---|
| 324 | *d*) boost_rt_d=$boost_rtopt;; #(
|
|---|
| 325 | *[[sgpn]]*) # Insert the `d' at the right place (in between `sg' and `pn')
|
|---|
| 326 | boost_rt_d=`echo "$boost_rtopt" | sed 's/\(s*g*\)\(p*n*\)/\1\2/'`;; #(
|
|---|
| 327 | *) boost_rt_d='-d';;
|
|---|
| 328 | esac
|
|---|
| 329 | # If the PREFERRED-RT-OPT are not empty, prepend a `-'.
|
|---|
| 330 | test -n "$boost_rtopt" && boost_rtopt="-$boost_rtopt"
|
|---|
| 331 | $boost_guess_use_mt && boost_mt=-mt
|
|---|
| 332 | # Look for the abs path the static archive.
|
|---|
| 333 | # $libext is computed by Libtool but let's make sure it's non empty.
|
|---|
| 334 | test -z "$libext" &&
|
|---|
| 335 | AC_MSG_ERROR([the libext variable is empty, did you invoke Libtool?])
|
|---|
| 336 | boost_save_ac_objext=$ac_objext
|
|---|
| 337 | # Generate the test file.
|
|---|
| 338 | AC_LANG_CONFTEST([AC_LANG_PROGRAM([#include <$3>
|
|---|
| 339 | $5], [$4])])
|
|---|
| 340 | dnl Optimization hacks: compiling C++ is slow, especially with Boost. What
|
|---|
| 341 | dnl we're trying to do here is guess the right combination of link flags
|
|---|
| 342 | dnl (LIBS / LDFLAGS) to use a given library. This can take several
|
|---|
| 343 | dnl iterations before it succeeds and is thus *very* slow. So what we do
|
|---|
| 344 | dnl instead is that we compile the code first (and thus get an object file,
|
|---|
| 345 | dnl typically conftest.o). Then we try various combinations of link flags
|
|---|
| 346 | dnl until we succeed to link conftest.o in an executable. The problem is
|
|---|
| 347 | dnl that the various TRY_LINK / COMPILE_IFELSE macros of Autoconf always
|
|---|
| 348 | dnl remove all the temporary files including conftest.o. So the trick here
|
|---|
| 349 | dnl is to temporarily change the value of ac_objext so that conftest.o is
|
|---|
| 350 | dnl preserved accross tests. This is obviously fragile and I will burn in
|
|---|
| 351 | dnl hell for not respecting Autoconf's documented interfaces, but in the
|
|---|
| 352 | dnl mean time, it optimizes the macro by a factor of 5 to 30.
|
|---|
| 353 | dnl Another small optimization: the first argument of AC_COMPILE_IFELSE left
|
|---|
| 354 | dnl empty because the test file is generated only once above (before we
|
|---|
| 355 | dnl start the for loops).
|
|---|
| 356 | AC_COMPILE_IFELSE([],
|
|---|
| 357 | [ac_objext=do_not_rm_me_plz],
|
|---|
| 358 | [AC_MSG_ERROR([cannot compile a test that uses Boost $1])])
|
|---|
| 359 | ac_objext=$boost_save_ac_objext
|
|---|
| 360 | boost_failed_libs=
|
|---|
| 361 | # Don't bother to ident the 6 nested for loops, only the 2 innermost ones
|
|---|
| 362 | # matter.
|
|---|
| 363 | for boost_tag_ in -$boost_cv_lib_tag ''; do
|
|---|
| 364 | for boost_ver_ in -$boost_cv_lib_version ''; do
|
|---|
| 365 | for boost_mt_ in $boost_mt -mt ''; do
|
|---|
| 366 | for boost_rtopt_ in $boost_rtopt '' -d; do
|
|---|
| 367 | for boost_lib in \
|
|---|
| 368 | boost_$1$boost_tag_$boost_mt_$boost_rtopt_$boost_ver_ \
|
|---|
| 369 | boost_$1$boost_tag_$boost_rtopt_$boost_ver_ \
|
|---|
| 370 | boost_$1$boost_tag_$boost_mt_$boost_ver_ \
|
|---|
| 371 | boost_$1$boost_tag_$boost_ver_
|
|---|
| 372 | do
|
|---|
| 373 | # Avoid testing twice the same lib
|
|---|
| 374 | case $boost_failed_libs in #(
|
|---|
| 375 | *@$boost_lib@*) continue;;
|
|---|
| 376 | esac
|
|---|
| 377 | # If with_boost is empty, we'll search in /lib first, which is not quite
|
|---|
| 378 | # right so instead we'll try to a location based on where the headers are.
|
|---|
| 379 | boost_tmp_lib=$with_boost
|
|---|
| 380 | test x"$with_boost" = x && boost_tmp_lib=${boost_cv_inc_path%/include}
|
|---|
| 381 | for boost_ldpath in "$boost_tmp_lib/lib" '' \
|
|---|
| 382 | /opt/local/lib* /usr/local/lib* /opt/lib* /usr/lib* \
|
|---|
| 383 | "$with_boost" C:/Boost/lib /lib*
|
|---|
| 384 | do
|
|---|
| 385 | test -e "$boost_ldpath" || continue
|
|---|
| 386 | boost_save_LDFLAGS=$LDFLAGS
|
|---|
| 387 | # Are we looking for a static library?
|
|---|
| 388 | case $boost_ldpath:$boost_rtopt_ in #(
|
|---|
| 389 | *?*:*s*) # Yes (Non empty boost_ldpath + s in rt opt)
|
|---|
| 390 | Boost_lib_LIBS="$boost_ldpath/lib$boost_lib.$libext"
|
|---|
| 391 | test -e "$Boost_lib_LIBS" || continue;; #(
|
|---|
| 392 | *) # No: use -lboost_foo to find the shared library.
|
|---|
| 393 | Boost_lib_LIBS="-l$boost_lib";;
|
|---|
| 394 | esac
|
|---|
| 395 | boost_save_LIBS=$LIBS
|
|---|
| 396 | LIBS="$Boost_lib_LIBS $LIBS"
|
|---|
| 397 | test x"$boost_ldpath" != x && LDFLAGS="$LDFLAGS -L$boost_ldpath"
|
|---|
| 398 | dnl First argument of AC_LINK_IFELSE left empty because the test file is
|
|---|
| 399 | dnl generated only once above (before we start the for loops).
|
|---|
| 400 | _BOOST_AC_LINK_IFELSE([],
|
|---|
| 401 | [Boost_lib=yes], [Boost_lib=no])
|
|---|
| 402 | ac_objext=$boost_save_ac_objext
|
|---|
| 403 | LDFLAGS=$boost_save_LDFLAGS
|
|---|
| 404 | LIBS=$boost_save_LIBS
|
|---|
| 405 | if test x"$Boost_lib" = xyes; then
|
|---|
| 406 | Boost_lib_LDFLAGS="-L$boost_ldpath -Wl,-R$boost_ldpath"
|
|---|
| 407 | Boost_lib_LDPATH="$boost_ldpath"
|
|---|
| 408 | break 6
|
|---|
| 409 | else
|
|---|
| 410 | boost_failed_libs="$boost_failed_libs@$boost_lib@"
|
|---|
| 411 | fi
|
|---|
| 412 | done
|
|---|
| 413 | done
|
|---|
| 414 | done
|
|---|
| 415 | done
|
|---|
| 416 | done
|
|---|
| 417 | done
|
|---|
| 418 | rm -f conftest.$ac_objext
|
|---|
| 419 | ])
|
|---|
| 420 | case $Boost_lib in #(
|
|---|
| 421 | no) _AC_MSG_LOG_CONFTEST
|
|---|
| 422 | AC_MSG_ERROR([cannot find the flags to link with Boost $1])
|
|---|
| 423 | ;;
|
|---|
| 424 | esac
|
|---|
| 425 | AC_SUBST(AS_TR_CPP([BOOST_$1_LDFLAGS]), [$Boost_lib_LDFLAGS])dnl
|
|---|
| 426 | AC_SUBST(AS_TR_CPP([BOOST_$1_LDPATH]), [$Boost_lib_LDPATH])dnl
|
|---|
| 427 | AC_SUBST([BOOST_LDPATH], [$Boost_lib_LDPATH])dnl
|
|---|
| 428 | AC_SUBST(AS_TR_CPP([BOOST_$1_LIBS]), [$Boost_lib_LIBS])dnl
|
|---|
| 429 | CPPFLAGS=$boost_save_CPPFLAGS
|
|---|
| 430 | AS_VAR_POPDEF([Boost_lib])dnl
|
|---|
| 431 | AS_VAR_POPDEF([Boost_lib_LDFLAGS])dnl
|
|---|
| 432 | AS_VAR_POPDEF([Boost_lib_LDPATH])dnl
|
|---|
| 433 | AS_VAR_POPDEF([Boost_lib_LIBS])dnl
|
|---|
| 434 | AC_LANG_POP([C++])dnl
|
|---|
| 435 | fi
|
|---|
| 436 | ])# BOOST_FIND_LIB
|
|---|
| 437 |
|
|---|
| 438 |
|
|---|
| 439 | # --------------------------------------- #
|
|---|
| 440 | # Checks for the various Boost libraries. #
|
|---|
| 441 | # --------------------------------------- #
|
|---|
| 442 |
|
|---|
| 443 | # List of boost libraries: http://www.boost.org/libs/libraries.htm
|
|---|
| 444 | # The page http://beta.boost.org/doc/libs is useful: it gives the first release
|
|---|
| 445 | # version of each library (among other things).
|
|---|
| 446 |
|
|---|
| 447 | # BOOST_DEFUN(LIBRARY, CODE)
|
|---|
| 448 | # --------------------------
|
|---|
| 449 | # Define BOOST_<LIBRARY-UPPERCASE> as a macro that runs CODE.
|
|---|
| 450 | #
|
|---|
| 451 | # Use indir to avoid the warning on underquoted macro name given to AC_DEFUN.
|
|---|
| 452 | m4_define([BOOST_DEFUN],
|
|---|
| 453 | [m4_indir([AC_DEFUN],
|
|---|
| 454 | m4_toupper([BOOST_$1]),
|
|---|
| 455 | [m4_pushdef([BOOST_Library], [$1])dnl
|
|---|
| 456 | $2
|
|---|
| 457 | m4_popdef([BOOST_Library])dnl
|
|---|
| 458 | ])
|
|---|
| 459 | ])
|
|---|
| 460 |
|
|---|
| 461 | # BOOST_ARRAY()
|
|---|
| 462 | # -------------
|
|---|
| 463 | # Look for Boost.Array
|
|---|
| 464 | BOOST_DEFUN([Array],
|
|---|
| 465 | [BOOST_FIND_HEADER([boost/array.hpp])])
|
|---|
| 466 |
|
|---|
| 467 |
|
|---|
| 468 | # BOOST_ASIO()
|
|---|
| 469 | # ------------
|
|---|
| 470 | # Look for Boost.Asio (new in Boost 1.35).
|
|---|
| 471 | BOOST_DEFUN([Asio],
|
|---|
| 472 | [AC_REQUIRE([BOOST_SYSTEM])dnl
|
|---|
| 473 | BOOST_FIND_HEADER([boost/asio.hpp])])
|
|---|
| 474 |
|
|---|
| 475 |
|
|---|
| 476 | # BOOST_BIND()
|
|---|
| 477 | # ------------
|
|---|
| 478 | # Look for Boost.Bind
|
|---|
| 479 | BOOST_DEFUN([Bind],
|
|---|
| 480 | [BOOST_FIND_HEADER([boost/bind.hpp])])
|
|---|
| 481 |
|
|---|
| 482 |
|
|---|
| 483 | # BOOST_CONVERSION()
|
|---|
| 484 | # ------------------
|
|---|
| 485 | # Look for Boost.Conversion (cast / lexical_cast)
|
|---|
| 486 | BOOST_DEFUN([Conversion],
|
|---|
| 487 | [BOOST_FIND_HEADER([boost/cast.hpp])
|
|---|
| 488 | BOOST_FIND_HEADER([boost/lexical_cast.hpp])
|
|---|
| 489 | ])# BOOST_CONVERSION
|
|---|
| 490 |
|
|---|
| 491 |
|
|---|
| 492 | # BOOST_DATE_TIME([PREFERRED-RT-OPT])
|
|---|
| 493 | # -----------------------------------
|
|---|
| 494 | # Look for Boost.Date_Time. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 495 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 496 | BOOST_DEFUN([Date_Time],
|
|---|
| 497 | [BOOST_FIND_LIB([date_time], [$1],
|
|---|
| 498 | [boost/date_time/posix_time/posix_time.hpp],
|
|---|
| 499 | [boost::posix_time::ptime t;])
|
|---|
| 500 | ])# BOOST_DATE_TIME
|
|---|
| 501 |
|
|---|
| 502 |
|
|---|
| 503 | # BOOST_FILESYSTEM([PREFERRED-RT-OPT])
|
|---|
| 504 | # ------------------------------------
|
|---|
| 505 | # Look for Boost.Filesystem. For the documentation of PREFERRED-RT-OPT, see
|
|---|
| 506 | # the documentation of BOOST_FIND_LIB above.
|
|---|
| 507 | # Do not check for boost/filesystem.hpp because this file was introduced in
|
|---|
| 508 | # 1.34.
|
|---|
| 509 | BOOST_DEFUN([Filesystem],
|
|---|
| 510 | [# Do we have to check for Boost.System? This link-time dependency was
|
|---|
| 511 | # added as of 1.35.0. If we have a version <1.35, we must not attempt to
|
|---|
| 512 | # find Boost.System as it didn't exist by then.
|
|---|
| 513 | if test $boost_major_version -ge 135; then
|
|---|
| 514 | BOOST_SYSTEM([$1])
|
|---|
| 515 | fi # end of the Boost.System check.
|
|---|
| 516 | boost_filesystem_save_LIBS=$LIBS
|
|---|
| 517 | boost_filesystem_save_LDFLAGS=$LDFLAGS
|
|---|
| 518 | m4_pattern_allow([^BOOST_SYSTEM_(LIBS|LDFLAGS)$])dnl
|
|---|
| 519 | LIBS="$LIBS $BOOST_SYSTEM_LIBS"
|
|---|
| 520 | LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
|
|---|
| 521 | BOOST_FIND_LIB([filesystem], [$1],
|
|---|
| 522 | [boost/filesystem/path.hpp], [boost::filesystem::path p;])
|
|---|
| 523 | if test $enable_static_boost = yes && test $boost_major_version -ge 135; then
|
|---|
| 524 | AC_SUBST([BOOST_FILESYSTEM_LIBS], ["$BOOST_FILESYSTEM_LIBS $BOOST_SYSTEM_LIBS"])
|
|---|
| 525 | fi
|
|---|
| 526 | LIBS=$boost_filesystem_save_LIBS
|
|---|
| 527 | LDFLAGS=$boost_filesystem_save_LDFLAGS
|
|---|
| 528 | ])# BOOST_FILESYSTEM
|
|---|
| 529 |
|
|---|
| 530 |
|
|---|
| 531 | # BOOST_FOREACH()
|
|---|
| 532 | # ---------------
|
|---|
| 533 | # Look for Boost.Foreach
|
|---|
| 534 | BOOST_DEFUN([Foreach],
|
|---|
| 535 | [BOOST_FIND_HEADER([boost/foreach.hpp])])
|
|---|
| 536 |
|
|---|
| 537 |
|
|---|
| 538 | # BOOST_FORMAT()
|
|---|
| 539 | # --------------
|
|---|
| 540 | # Look for Boost.Format
|
|---|
| 541 | # Note: we can't check for boost/format/format_fwd.hpp because the header isn't
|
|---|
| 542 | # standalone. It can't be compiled because it triggers the following error:
|
|---|
| 543 | # boost/format/detail/config_macros.hpp:88: error: 'locale' in namespace 'std'
|
|---|
| 544 | # does not name a type
|
|---|
| 545 | BOOST_DEFUN([Format],
|
|---|
| 546 | [BOOST_FIND_HEADER([boost/format.hpp])])
|
|---|
| 547 |
|
|---|
| 548 |
|
|---|
| 549 | # BOOST_FUNCTION()
|
|---|
| 550 | # ----------------
|
|---|
| 551 | # Look for Boost.Function
|
|---|
| 552 | BOOST_DEFUN([Function],
|
|---|
| 553 | [BOOST_FIND_HEADER([boost/function.hpp])])
|
|---|
| 554 |
|
|---|
| 555 |
|
|---|
| 556 | # BOOST_GRAPH([PREFERRED-RT-OPT])
|
|---|
| 557 | # -------------------------------
|
|---|
| 558 | # Look for Boost.Graphs. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 559 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 560 | BOOST_DEFUN([Graph],
|
|---|
| 561 | [BOOST_FIND_LIB([graph], [$1],
|
|---|
| 562 | [boost/graph/adjacency_list.hpp], [boost::adjacency_list<> g;])
|
|---|
| 563 | ])# BOOST_GRAPH
|
|---|
| 564 |
|
|---|
| 565 |
|
|---|
| 566 | # BOOST_IOSTREAMS([PREFERRED-RT-OPT])
|
|---|
| 567 | # -----------------------------------
|
|---|
| 568 | # Look for Boost.IOStreams. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 569 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 570 | BOOST_DEFUN([IOStreams],
|
|---|
| 571 | [BOOST_FIND_LIB([iostreams], [$1],
|
|---|
| 572 | [boost/iostreams/device/file_descriptor.hpp],
|
|---|
| 573 | [boost::iostreams::file_descriptor fd; fd.close();])
|
|---|
| 574 | ])# BOOST_IOSTREAMS
|
|---|
| 575 |
|
|---|
| 576 |
|
|---|
| 577 | # BOOST_HASH()
|
|---|
| 578 | # ------------
|
|---|
| 579 | # Look for Boost.Functional/Hash
|
|---|
| 580 | BOOST_DEFUN([Hash],
|
|---|
| 581 | [BOOST_FIND_HEADER([boost/functional/hash.hpp])])
|
|---|
| 582 |
|
|---|
| 583 |
|
|---|
| 584 | # BOOST_LAMBDA()
|
|---|
| 585 | # --------------
|
|---|
| 586 | # Look for Boost.Lambda
|
|---|
| 587 | BOOST_DEFUN([Lambda],
|
|---|
| 588 | [BOOST_FIND_HEADER([boost/lambda/lambda.hpp])])
|
|---|
| 589 |
|
|---|
| 590 |
|
|---|
| 591 | # BOOST_MATH()
|
|---|
| 592 | # ------------
|
|---|
| 593 | # Look for Boost.Math
|
|---|
| 594 | # TODO: This library isn't header-only but it comes in multiple different
|
|---|
| 595 | # flavors that don't play well with BOOST_FIND_LIB (e.g, libboost_math_c99,
|
|---|
| 596 | # libboost_math_c99f, libboost_math_c99l, libboost_math_tr1,
|
|---|
| 597 | # libboost_math_tr1f, libboost_math_tr1l). This macro must be fixed to do the
|
|---|
| 598 | # right thing anyway.
|
|---|
| 599 | BOOST_DEFUN([Math],
|
|---|
| 600 | [BOOST_FIND_HEADER([boost/math/special_functions.hpp])])
|
|---|
| 601 |
|
|---|
| 602 |
|
|---|
| 603 | # BOOST_MULTIARRAY()
|
|---|
| 604 | # ------------------
|
|---|
| 605 | # Look for Boost.MultiArray
|
|---|
| 606 | BOOST_DEFUN([MultiArray],
|
|---|
| 607 | [BOOST_FIND_HEADER([boost/multi_array.hpp])])
|
|---|
| 608 |
|
|---|
| 609 |
|
|---|
| 610 | # BOOST_NUMERIC_CONVERSION()
|
|---|
| 611 | # --------------------------
|
|---|
| 612 | # Look for Boost.NumericConversion (policy-based numeric conversion)
|
|---|
| 613 | BOOST_DEFUN([Numeric_Conversion],
|
|---|
| 614 | [BOOST_FIND_HEADER([boost/numeric/conversion/converter.hpp])
|
|---|
| 615 | ])# BOOST_NUMERIC_CONVERSION
|
|---|
| 616 |
|
|---|
| 617 |
|
|---|
| 618 | # BOOST_OPTIONAL()
|
|---|
| 619 | # ----------------
|
|---|
| 620 | # Look for Boost.Optional
|
|---|
| 621 | BOOST_DEFUN([Optional],
|
|---|
| 622 | [BOOST_FIND_HEADER([boost/optional.hpp])])
|
|---|
| 623 |
|
|---|
| 624 |
|
|---|
| 625 | # BOOST_PREPROCESSOR()
|
|---|
| 626 | # --------------------
|
|---|
| 627 | # Look for Boost.Preprocessor
|
|---|
| 628 | BOOST_DEFUN([Preprocessor],
|
|---|
| 629 | [BOOST_FIND_HEADER([boost/preprocessor/repeat.hpp])])
|
|---|
| 630 |
|
|---|
| 631 |
|
|---|
| 632 | # BOOST_PROGRAM_OPTIONS([PREFERRED-RT-OPT])
|
|---|
| 633 | # -----------------------------------------
|
|---|
| 634 | # Look for Boost.Program_options. For the documentation of PREFERRED-RT-OPT,
|
|---|
| 635 | # see the documentation of BOOST_FIND_LIB above.
|
|---|
| 636 | BOOST_DEFUN([Program_Options],
|
|---|
| 637 | [BOOST_FIND_LIB([program_options], [$1],
|
|---|
| 638 | [boost/program_options.hpp],
|
|---|
| 639 | [boost::program_options::options_description d("test");])
|
|---|
| 640 | ])# BOOST_PROGRAM_OPTIONS
|
|---|
| 641 |
|
|---|
| 642 |
|
|---|
| 643 |
|
|---|
| 644 | # _BOOST_PYTHON_CONFIG(VARIABLE, FLAG)
|
|---|
| 645 | # ------------------------------------
|
|---|
| 646 | # Save VARIABLE, and define it via `python-config --FLAG`.
|
|---|
| 647 | # Substitute BOOST_PYTHON_VARIABLE.
|
|---|
| 648 | m4_define([_BOOST_PYTHON_CONFIG],
|
|---|
| 649 | [AC_SUBST([BOOST_PYTHON_$1],
|
|---|
| 650 | [`python-config --$2 2>/dev/null`])dnl
|
|---|
| 651 | boost_python_save_$1=$$1
|
|---|
| 652 | $1="$$1 $BOOST_PYTHON_$1"])
|
|---|
| 653 |
|
|---|
| 654 |
|
|---|
| 655 | # BOOST_PYTHON([PREFERRED-RT-OPT])
|
|---|
| 656 | # --------------------------------
|
|---|
| 657 | # Look for Boost.Python. For the documentation of PREFERRED-RT-OPT,
|
|---|
| 658 | # see the documentation of BOOST_FIND_LIB above.
|
|---|
| 659 | BOOST_DEFUN([Python],
|
|---|
| 660 | [_BOOST_PYTHON_CONFIG([CPPFLAGS], [includes])
|
|---|
| 661 | _BOOST_PYTHON_CONFIG([LDFLAGS], [ldflags])
|
|---|
| 662 | _BOOST_PYTHON_CONFIG([LIBS], [libs])
|
|---|
| 663 | m4_pattern_allow([^BOOST_PYTHON_MODULE$])dnl
|
|---|
| 664 | BOOST_FIND_LIB([python], [$1],
|
|---|
| 665 | [boost/python.hpp],
|
|---|
| 666 | [], [BOOST_PYTHON_MODULE(empty) {}])
|
|---|
| 667 | CPPFLAGS=$boost_python_save_CPPFLAGS
|
|---|
| 668 | LDFLAGS=$boost_python_save_LDFLAGS
|
|---|
| 669 | LIBS=$boost_python_save_LIBS
|
|---|
| 670 | ])# BOOST_PYTHON
|
|---|
| 671 |
|
|---|
| 672 |
|
|---|
| 673 | # BOOST_REF()
|
|---|
| 674 | # -----------
|
|---|
| 675 | # Look for Boost.Ref
|
|---|
| 676 | BOOST_DEFUN([Ref],
|
|---|
| 677 | [BOOST_FIND_HEADER([boost/ref.hpp])])
|
|---|
| 678 |
|
|---|
| 679 |
|
|---|
| 680 | # BOOST_REGEX([PREFERRED-RT-OPT])
|
|---|
| 681 | # -------------------------------
|
|---|
| 682 | # Look for Boost.Regex. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 683 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 684 | BOOST_DEFUN([Regex],
|
|---|
| 685 | [BOOST_FIND_LIB([regex], [$1],
|
|---|
| 686 | [boost/regex.hpp],
|
|---|
| 687 | [boost::regex exp("*"); boost::regex_match("foo", exp);])
|
|---|
| 688 | ])# BOOST_REGEX
|
|---|
| 689 |
|
|---|
| 690 |
|
|---|
| 691 | # BOOST_SERIALIZATION([PREFERRED-RT-OPT])
|
|---|
| 692 | # ---------------------------------------
|
|---|
| 693 | # Look for Boost.Serialization. For the documentation of PREFERRED-RT-OPT, see
|
|---|
| 694 | # the documentation of BOOST_FIND_LIB above.
|
|---|
| 695 | BOOST_DEFUN([Serialization],
|
|---|
| 696 | [BOOST_FIND_LIB([serialization], [$1],
|
|---|
| 697 | [boost/archive/text_oarchive.hpp],
|
|---|
| 698 | [std::ostream* o = 0; // Cheap way to get an ostream...
|
|---|
| 699 | boost::archive::text_oarchive t(*o);])
|
|---|
| 700 | ])# BOOST_SIGNALS
|
|---|
| 701 |
|
|---|
| 702 |
|
|---|
| 703 | # BOOST_SIGNALS([PREFERRED-RT-OPT])
|
|---|
| 704 | # ---------------------------------
|
|---|
| 705 | # Look for Boost.Signals. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 706 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 707 | BOOST_DEFUN([Signals],
|
|---|
| 708 | [BOOST_FIND_LIB([signals], [$1],
|
|---|
| 709 | [boost/signal.hpp],
|
|---|
| 710 | [boost::signal<void ()> s;])
|
|---|
| 711 | ])# BOOST_SIGNALS
|
|---|
| 712 |
|
|---|
| 713 |
|
|---|
| 714 | # BOOST_SMART_PTR()
|
|---|
| 715 | # -----------------
|
|---|
| 716 | # Look for Boost.SmartPtr
|
|---|
| 717 | BOOST_DEFUN([Smart_Ptr],
|
|---|
| 718 | [BOOST_FIND_HEADER([boost/scoped_ptr.hpp])
|
|---|
| 719 | BOOST_FIND_HEADER([boost/shared_ptr.hpp])
|
|---|
| 720 | ])
|
|---|
| 721 |
|
|---|
| 722 |
|
|---|
| 723 | # BOOST_STATICASSERT()
|
|---|
| 724 | # --------------------
|
|---|
| 725 | # Look for Boost.StaticAssert
|
|---|
| 726 | BOOST_DEFUN([StaticAssert],
|
|---|
| 727 | [BOOST_FIND_HEADER([boost/static_assert.hpp])])
|
|---|
| 728 |
|
|---|
| 729 |
|
|---|
| 730 | # BOOST_STRING_ALGO()
|
|---|
| 731 | # -------------------
|
|---|
| 732 | # Look for Boost.StringAlgo
|
|---|
| 733 | BOOST_DEFUN([String_Algo],
|
|---|
| 734 | [BOOST_FIND_HEADER([boost/algorithm/string.hpp])
|
|---|
| 735 | ])
|
|---|
| 736 |
|
|---|
| 737 |
|
|---|
| 738 | # BOOST_SYSTEM([PREFERRED-RT-OPT])
|
|---|
| 739 | # --------------------------------
|
|---|
| 740 | # Look for Boost.System. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 741 | # documentation of BOOST_FIND_LIB above. This library was introduced in Boost
|
|---|
| 742 | # 1.35.0.
|
|---|
| 743 | BOOST_DEFUN([System],
|
|---|
| 744 | [BOOST_FIND_LIB([system], [$1],
|
|---|
| 745 | [boost/system/error_code.hpp],
|
|---|
| 746 | [boost::system::error_code e; e.clear();])
|
|---|
| 747 | ])# BOOST_SYSTEM
|
|---|
| 748 |
|
|---|
| 749 |
|
|---|
| 750 | # BOOST_TEST([PREFERRED-RT-OPT])
|
|---|
| 751 | # ------------------------------
|
|---|
| 752 | # Look for Boost.Test. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 753 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 754 | BOOST_DEFUN([Test],
|
|---|
| 755 | [m4_pattern_allow([^BOOST_CHECK$])dnl
|
|---|
| 756 | BOOST_FIND_LIB([unit_test_framework], [$1],
|
|---|
| 757 | [boost/test/unit_test.hpp], [BOOST_CHECK(2 == 2);],
|
|---|
| 758 | [using boost::unit_test::test_suite;
|
|---|
| 759 | test_suite* init_unit_test_suite(int argc, char ** argv)
|
|---|
| 760 | { return NULL; }])
|
|---|
| 761 | ])# BOOST_TEST
|
|---|
| 762 |
|
|---|
| 763 |
|
|---|
| 764 | # BOOST_THREADS([PREFERRED-RT-OPT])
|
|---|
| 765 | # ---------------------------------
|
|---|
| 766 | # Look for Boost.Thread. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 767 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 768 | # FIXME: Provide an alias "BOOST_THREAD".
|
|---|
| 769 | BOOST_DEFUN([Threads],
|
|---|
| 770 | [dnl Having the pthread flag is required at least on GCC3 where
|
|---|
| 771 | dnl boost/thread.hpp would complain if we try to compile without
|
|---|
| 772 | dnl -pthread on GNU/Linux.
|
|---|
| 773 | AC_REQUIRE([_BOOST_PTHREAD_FLAG])dnl
|
|---|
| 774 | boost_threads_save_LIBS=$LIBS
|
|---|
| 775 | boost_threads_save_CPPFLAGS=$CPPFLAGS
|
|---|
| 776 | LIBS="$LIBS $boost_cv_pthread_flag"
|
|---|
| 777 | # Yes, we *need* to put the -pthread thing in CPPFLAGS because with GCC3,
|
|---|
| 778 | # boost/thread.hpp will trigger a #error if -pthread isn't used:
|
|---|
| 779 | # boost/config/requires_threads.hpp:47:5: #error "Compiler threading support
|
|---|
| 780 | # is not turned on. Please set the correct command line options for
|
|---|
| 781 | # threading: -pthread (Linux), -pthreads (Solaris) or -mthreads (Mingw32)"
|
|---|
| 782 | CPPFLAGS="$CPPFLAGS $boost_cv_pthread_flag"
|
|---|
| 783 | BOOST_FIND_LIB([thread], [$1],
|
|---|
| 784 | [boost/thread.hpp], [boost::thread t; boost::mutex m;])
|
|---|
| 785 | BOOST_THREAD_LIBS="$BOOST_THREAD_LIBS $boost_cv_pthread_flag"
|
|---|
| 786 | BOOST_CPPFLAGS="$BOOST_CPPFLAGS $boost_cv_pthread_flag"
|
|---|
| 787 | LIBS=$boost_threads_save_LIBS
|
|---|
| 788 | CPPFLAGS=$boost_threads_save_CPPFLAGS
|
|---|
| 789 | ])# BOOST_THREADS
|
|---|
| 790 |
|
|---|
| 791 |
|
|---|
| 792 | # BOOST_TOKENIZER()
|
|---|
| 793 | # -----------------
|
|---|
| 794 | # Look for Boost.Tokenizer
|
|---|
| 795 | BOOST_DEFUN([Tokenizer],
|
|---|
| 796 | [BOOST_FIND_HEADER([boost/tokenizer.hpp])])
|
|---|
| 797 |
|
|---|
| 798 |
|
|---|
| 799 | # BOOST_TRIBOOL()
|
|---|
| 800 | # ---------------
|
|---|
| 801 | # Look for Boost.Tribool
|
|---|
| 802 | BOOST_DEFUN([Tribool],
|
|---|
| 803 | [BOOST_FIND_HEADER([boost/logic/tribool_fwd.hpp])
|
|---|
| 804 | BOOST_FIND_HEADER([boost/logic/tribool.hpp])
|
|---|
| 805 | ])
|
|---|
| 806 |
|
|---|
| 807 |
|
|---|
| 808 | # BOOST_TUPLE()
|
|---|
| 809 | # -------------
|
|---|
| 810 | # Look for Boost.Tuple
|
|---|
| 811 | BOOST_DEFUN([Tuple],
|
|---|
| 812 | [BOOST_FIND_HEADER([boost/tuple/tuple.hpp])])
|
|---|
| 813 |
|
|---|
| 814 |
|
|---|
| 815 | # BOOST_TYPETRAITS()
|
|---|
| 816 | # --------------------
|
|---|
| 817 | # Look for Boost.TypeTraits
|
|---|
| 818 | BOOST_DEFUN([TypeTraits],
|
|---|
| 819 | [BOOST_FIND_HEADER([boost/type_traits.hpp])])
|
|---|
| 820 |
|
|---|
| 821 |
|
|---|
| 822 | # BOOST_UTILITY()
|
|---|
| 823 | # ---------------
|
|---|
| 824 | # Look for Boost.Utility (noncopyable, result_of, base-from-member idiom,
|
|---|
| 825 | # etc.)
|
|---|
| 826 | BOOST_DEFUN([Utility],
|
|---|
| 827 | [BOOST_FIND_HEADER([boost/utility.hpp])])
|
|---|
| 828 |
|
|---|
| 829 |
|
|---|
| 830 | # BOOST_VARIANT()
|
|---|
| 831 | # ---------------
|
|---|
| 832 | # Look for Boost.Variant.
|
|---|
| 833 | BOOST_DEFUN([Variant],
|
|---|
| 834 | [BOOST_FIND_HEADER([boost/variant/variant_fwd.hpp])
|
|---|
| 835 | BOOST_FIND_HEADER([boost/variant.hpp])])
|
|---|
| 836 |
|
|---|
| 837 |
|
|---|
| 838 | # BOOST_WAVE([PREFERRED-RT-OPT])
|
|---|
| 839 | # ------------------------------
|
|---|
| 840 | # NOTE: If you intend to use Wave/Spirit with thread support, make sure you
|
|---|
| 841 | # call BOOST_THREADS first.
|
|---|
| 842 | # Look for Boost.Wave. For the documentation of PREFERRED-RT-OPT, see the
|
|---|
| 843 | # documentation of BOOST_FIND_LIB above.
|
|---|
| 844 | BOOST_DEFUN([Wave],
|
|---|
| 845 | [AC_REQUIRE([BOOST_FILESYSTEM])dnl
|
|---|
| 846 | AC_REQUIRE([BOOST_DATE_TIME])dnl
|
|---|
| 847 | boost_wave_save_LIBS=$LIBS
|
|---|
| 848 | boost_wave_save_LDFLAGS=$LDFLAGS
|
|---|
| 849 | m4_pattern_allow([^BOOST_((FILE)?SYSTEM|DATE_TIME|THREAD)_(LIBS|LDFLAGS)$])dnl
|
|---|
| 850 | LIBS="$LIBS $BOOST_SYSTEM_LIBS $BOOST_FILESYSTEM_LIBS $BOOST_DATE_TIME_LIBS\
|
|---|
| 851 | $BOOST_THREAD_LIBS"
|
|---|
| 852 | LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS $BOOST_FILESYSTEM_LDFLAGS\
|
|---|
| 853 | $BOOST_DATE_TIME_LDFLAGS $BOOST_THREAD_LDFLAGS"
|
|---|
| 854 | BOOST_FIND_LIB([wave], [$1],
|
|---|
| 855 | [boost/wave.hpp],
|
|---|
| 856 | [boost::wave::token_id id; get_token_name(id);])
|
|---|
| 857 | LIBS=$boost_wave_save_LIBS
|
|---|
| 858 | LDFLAGS=$boost_wave_save_LDFLAGS
|
|---|
| 859 | ])# BOOST_WAVE
|
|---|
| 860 |
|
|---|
| 861 |
|
|---|
| 862 | # BOOST_XPRESSIVE()
|
|---|
| 863 | # -----------------
|
|---|
| 864 | # Look for Boost.Xpressive (new since 1.36.0).
|
|---|
| 865 | BOOST_DEFUN([Xpressive],
|
|---|
| 866 | [BOOST_FIND_HEADER([boost/xpressive/xpressive.hpp])])
|
|---|
| 867 |
|
|---|
| 868 |
|
|---|
| 869 | # ----------------- #
|
|---|
| 870 | # Internal helpers. #
|
|---|
| 871 | # ----------------- #
|
|---|
| 872 |
|
|---|
| 873 |
|
|---|
| 874 | # _BOOST_PTHREAD_FLAG()
|
|---|
| 875 | # ---------------------
|
|---|
| 876 | # Internal helper for BOOST_THREADS. Based on ACX_PTHREAD:
|
|---|
| 877 | # http://autoconf-archive.cryp.to/acx_pthread.html
|
|---|
| 878 | AC_DEFUN([_BOOST_PTHREAD_FLAG],
|
|---|
| 879 | [AC_REQUIRE([AC_PROG_CXX])dnl
|
|---|
| 880 | AC_REQUIRE([AC_CANONICAL_HOST])dnl
|
|---|
| 881 | AC_LANG_PUSH([C++])dnl
|
|---|
| 882 | AC_CACHE_CHECK([for the flags needed to use pthreads], [boost_cv_pthread_flag],
|
|---|
| 883 | [ boost_cv_pthread_flag=
|
|---|
| 884 | # The ordering *is* (sometimes) important. Some notes on the
|
|---|
| 885 | # individual items follow:
|
|---|
| 886 | # (none): in case threads are in libc; should be tried before -Kthread and
|
|---|
| 887 | # other compiler flags to prevent continual compiler warnings
|
|---|
| 888 | # -lpthreads: AIX (must check this before -lpthread)
|
|---|
| 889 | # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
|
|---|
| 890 | # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
|
|---|
| 891 | # -llthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
|
|---|
| 892 | # -pthread: GNU Linux/GCC (kernel threads), BSD/GCC (userland threads)
|
|---|
| 893 | # -pthreads: Solaris/GCC
|
|---|
| 894 | # -mthreads: MinGW32/GCC, Lynx/GCC
|
|---|
| 895 | # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
|
|---|
| 896 | # doesn't hurt to check since this sometimes defines pthreads too;
|
|---|
| 897 | # also defines -D_REENTRANT)
|
|---|
| 898 | # ... -mt is also the pthreads flag for HP/aCC
|
|---|
| 899 | # -lpthread: GNU Linux, etc.
|
|---|
| 900 | # --thread-safe: KAI C++
|
|---|
| 901 | case $host_os in #(
|
|---|
| 902 | *solaris*)
|
|---|
| 903 | # On Solaris (at least, for some versions), libc contains stubbed
|
|---|
| 904 | # (non-functional) versions of the pthreads routines, so link-based
|
|---|
| 905 | # tests will erroneously succeed. (We need to link with -pthreads/-mt/
|
|---|
| 906 | # -lpthread.) (The stubs are missing pthread_cleanup_push, or rather
|
|---|
| 907 | # a function called by this macro, so we could check for that, but
|
|---|
| 908 | # who knows whether they'll stub that too in a future libc.) So,
|
|---|
| 909 | # we'll just look for -pthreads and -lpthread first:
|
|---|
| 910 | boost_pthread_flags="-pthreads -lpthread -mt -pthread";; #(
|
|---|
| 911 | *)
|
|---|
| 912 | boost_pthread_flags="-lpthreads -Kthread -kthread -llthread -pthread \
|
|---|
| 913 | -pthreads -mthreads -lpthread --thread-safe -mt";;
|
|---|
| 914 | esac
|
|---|
| 915 | # Generate the test file.
|
|---|
| 916 | AC_LANG_CONFTEST([AC_LANG_PROGRAM([#include <pthread.h>],
|
|---|
| 917 | [pthread_t th; pthread_join(th, 0);
|
|---|
| 918 | pthread_attr_init(0); pthread_cleanup_push(0, 0);
|
|---|
| 919 | pthread_create(0,0,0,0); pthread_cleanup_pop(0);])])
|
|---|
| 920 | for boost_pthread_flag in '' $boost_pthread_flags; do
|
|---|
| 921 | boost_pthread_ok=false
|
|---|
| 922 | dnl Re-use the test file already generated.
|
|---|
| 923 | boost_pthreads__save_LIBS=$LIBS
|
|---|
| 924 | LIBS="$LIBS $boost_pthread_flag"
|
|---|
| 925 | AC_LINK_IFELSE([],
|
|---|
| 926 | [if grep ".*$boost_pthread_flag" conftest.err; then
|
|---|
| 927 | echo "This flag seems to have triggered warnings" >&AS_MESSAGE_LOG_FD
|
|---|
| 928 | else
|
|---|
| 929 | boost_pthread_ok=:; boost_cv_pthread_flag=$boost_pthread_flag
|
|---|
| 930 | fi])
|
|---|
| 931 | LIBS=$boost_pthreads__save_LIBS
|
|---|
| 932 | $boost_pthread_ok && break
|
|---|
| 933 | done
|
|---|
| 934 | ])
|
|---|
| 935 | AC_LANG_POP([C++])dnl
|
|---|
| 936 | ])# _BOOST_PTHREAD_FLAG
|
|---|
| 937 |
|
|---|
| 938 |
|
|---|
| 939 | # _BOOST_gcc_test(MAJOR, MINOR)
|
|---|
| 940 | # -----------------------------
|
|---|
| 941 | # Internal helper for _BOOST_FIND_COMPILER_TAG.
|
|---|
| 942 | m4_define([_BOOST_gcc_test],
|
|---|
| 943 | ["defined __GNUC__ && __GNUC__ == $1 && __GNUC_MINOR__ == $2 && !defined __ICC @ gcc$1$2"])dnl
|
|---|
| 944 |
|
|---|
| 945 |
|
|---|
| 946 | # _BOOST_FIND_COMPILER_TAG()
|
|---|
| 947 | # --------------------------
|
|---|
| 948 | # Internal. When Boost is installed without --layout=system, each library
|
|---|
| 949 | # filename will hold a suffix that encodes the compiler used during the
|
|---|
| 950 | # build. The Boost build system seems to call this a `tag'.
|
|---|
| 951 | AC_DEFUN([_BOOST_FIND_COMPILER_TAG],
|
|---|
| 952 | [AC_REQUIRE([AC_PROG_CXX])dnl
|
|---|
| 953 | AC_REQUIRE([AC_CANONICAL_HOST])dnl
|
|---|
| 954 | AC_CACHE_CHECK([for the toolset name used by Boost for $CXX], [boost_cv_lib_tag],
|
|---|
| 955 | [boost_cv_lib_tag=unknown
|
|---|
| 956 | if test x$boost_cv_inc_path != xno; then
|
|---|
| 957 | AC_LANG_PUSH([C++])dnl
|
|---|
| 958 | # The following tests are mostly inspired by boost/config/auto_link.hpp
|
|---|
| 959 | # The list is sorted to most recent/common to oldest compiler (in order
|
|---|
| 960 | # to increase the likelihood of finding the right compiler with the
|
|---|
| 961 | # least number of compilation attempt).
|
|---|
| 962 | # Beware that some tests are sensible to the order (for instance, we must
|
|---|
| 963 | # look for MinGW before looking for GCC3).
|
|---|
| 964 | # I used one compilation test per compiler with a #error to recognize
|
|---|
| 965 | # each compiler so that it works even when cross-compiling (let me know
|
|---|
| 966 | # if you know a better approach).
|
|---|
| 967 | # Known missing tags (known from Boost's tools/build/v2/tools/common.jam):
|
|---|
| 968 | # como, edg, kcc, bck, mp, sw, tru, xlc
|
|---|
| 969 | # I'm not sure about my test for `il' (be careful: Intel's ICC pre-defines
|
|---|
| 970 | # the same defines as GCC's).
|
|---|
| 971 | for i in \
|
|---|
| 972 | _BOOST_gcc_test(4, 6) \
|
|---|
| 973 | _BOOST_gcc_test(4, 5) \
|
|---|
| 974 | _BOOST_gcc_test(4, 4) \
|
|---|
| 975 | _BOOST_gcc_test(4, 3) \
|
|---|
| 976 | _BOOST_gcc_test(4, 2) \
|
|---|
| 977 | _BOOST_gcc_test(4, 1) \
|
|---|
| 978 | _BOOST_gcc_test(4, 0) \
|
|---|
| 979 | "defined __GNUC__ && __GNUC__ == 3 && !defined __ICC \
|
|---|
| 980 | && (defined WIN32 || defined WINNT || defined _WIN32 || defined __WIN32 \
|
|---|
| 981 | || defined __WIN32__ || defined __WINNT || defined __WINNT__) @ mgw" \
|
|---|
| 982 | _BOOST_gcc_test(3, 4) \
|
|---|
| 983 | _BOOST_gcc_test(3, 3) \
|
|---|
| 984 | "defined _MSC_VER && _MSC_VER >= 1500 @ vc90" \
|
|---|
| 985 | "defined _MSC_VER && _MSC_VER == 1400 @ vc80" \
|
|---|
| 986 | _BOOST_gcc_test(3, 2) \
|
|---|
| 987 | "defined _MSC_VER && _MSC_VER == 1310 @ vc71" \
|
|---|
| 988 | _BOOST_gcc_test(3, 1) \
|
|---|
| 989 | _BOOST_gcc_test(3, 0) \
|
|---|
| 990 | "defined __BORLANDC__ @ bcb" \
|
|---|
| 991 | "defined __ICC && (defined __unix || defined __unix__) @ il" \
|
|---|
| 992 | "defined __ICL @ iw" \
|
|---|
| 993 | "defined _MSC_VER && _MSC_VER == 1300 @ vc7" \
|
|---|
| 994 | _BOOST_gcc_test(2, 95) \
|
|---|
| 995 | "defined __MWERKS__ && __MWERKS__ <= 0x32FF @ cw9" \
|
|---|
| 996 | "defined _MSC_VER && _MSC_VER < 1300 && !defined UNDER_CE @ vc6" \
|
|---|
| 997 | "defined _MSC_VER && _MSC_VER < 1300 && defined UNDER_CE @ evc4" \
|
|---|
| 998 | "defined __MWERKS__ && __MWERKS__ <= 0x31FF @ cw8"
|
|---|
| 999 | do
|
|---|
| 1000 | boost_tag_test=`expr "X$i" : 'X\([[^@]]*\) @ '`
|
|---|
| 1001 | boost_tag=`expr "X$i" : 'X[[^@]]* @ \(.*\)'`
|
|---|
| 1002 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|---|
| 1003 | #if $boost_tag_test
|
|---|
| 1004 | /* OK */
|
|---|
| 1005 | #else
|
|---|
| 1006 | # error $boost_tag_test
|
|---|
| 1007 | #endif
|
|---|
| 1008 | ]])], [boost_cv_lib_tag=$boost_tag; break], [])
|
|---|
| 1009 | done
|
|---|
| 1010 | AC_LANG_POP([C++])dnl
|
|---|
| 1011 | case $boost_cv_lib_tag in #(
|
|---|
| 1012 | # Some newer (>= 1.35?) versions of Boost seem to only use "gcc" as opposed
|
|---|
| 1013 | # to "gcc41" for instance.
|
|---|
| 1014 | *-gcc | *'-gcc ') :;; #( Don't re-add -gcc: it's already in there.
|
|---|
| 1015 | gcc*)
|
|---|
| 1016 | boost_tag_x=
|
|---|
| 1017 | case $host_os in #(
|
|---|
| 1018 | darwin*)
|
|---|
| 1019 | if test $boost_major_version -ge 136; then
|
|---|
| 1020 | # The `x' added in r46793 of Boost.
|
|---|
| 1021 | boost_tag_x=x
|
|---|
| 1022 | fi;;
|
|---|
| 1023 | esac
|
|---|
| 1024 | # We can specify multiple tags in this variable because it's used by
|
|---|
| 1025 | # BOOST_FIND_LIB that does a `for tag in -$boost_cv_lib_tag' ...
|
|---|
| 1026 | boost_cv_lib_tag="$boost_tag_x$boost_cv_lib_tag -${boost_tag_x}gcc"
|
|---|
| 1027 | ;; #(
|
|---|
| 1028 | unknown)
|
|---|
| 1029 | AC_MSG_WARN([[could not figure out which toolset name to use for $CXX]])
|
|---|
| 1030 | boost_cv_lib_tag=
|
|---|
| 1031 | ;;
|
|---|
| 1032 | esac
|
|---|
| 1033 | fi])dnl end of AC_CACHE_CHECK
|
|---|
| 1034 | ])# _BOOST_FIND_COMPILER_TAG
|
|---|
| 1035 |
|
|---|
| 1036 |
|
|---|
| 1037 | # _BOOST_GUESS_WHETHER_TO_USE_MT()
|
|---|
| 1038 | # --------------------------------
|
|---|
| 1039 | # Compile a small test to try to guess whether we should favor MT (Multi
|
|---|
| 1040 | # Thread) flavors of Boost. Sets boost_guess_use_mt accordingly.
|
|---|
| 1041 | AC_DEFUN([_BOOST_GUESS_WHETHER_TO_USE_MT],
|
|---|
| 1042 | [# Check whether we do better use `mt' even though we weren't ask to.
|
|---|
| 1043 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|---|
| 1044 | #if defined _REENTRANT || defined _MT || defined __MT__
|
|---|
| 1045 | /* use -mt */
|
|---|
| 1046 | #else
|
|---|
| 1047 | # error MT not needed
|
|---|
| 1048 | #endif
|
|---|
| 1049 | ]])], [boost_guess_use_mt=:], [boost_guess_use_mt=false])
|
|---|
| 1050 | ])
|
|---|
| 1051 |
|
|---|
| 1052 | # _BOOST_AC_LINK_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
|
|---|
| 1053 | # -------------------------------------------------------------------
|
|---|
| 1054 | # Fork of _AC_LINK_IFELSE that preserves conftest.o across calls. Fragile,
|
|---|
| 1055 | # will break when Autoconf changes its internals. Requires that you manually
|
|---|
| 1056 | # rm -f conftest.$ac_objext in between to really different tests, otherwise
|
|---|
| 1057 | # you will try to link a conftest.o left behind by a previous test.
|
|---|
| 1058 | # Used to aggressively optimize BOOST_FIND_LIB (see the big comment in this
|
|---|
| 1059 | # macro).
|
|---|
| 1060 | #
|
|---|
| 1061 | # Don't use "break" in the actions, as it would short-circuit some code
|
|---|
| 1062 | # this macro runs after the actions.
|
|---|
| 1063 | m4_define([_BOOST_AC_LINK_IFELSE],
|
|---|
| 1064 | [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
|
|---|
| 1065 | rm -f conftest$ac_exeext
|
|---|
| 1066 | boost_save_ac_ext=$ac_ext
|
|---|
| 1067 | boost_use_source=:
|
|---|
| 1068 | # If we already have a .o, re-use it. We change $ac_ext so that $ac_link
|
|---|
| 1069 | # tries to link the existing object file instead of compiling from source.
|
|---|
| 1070 | test -f conftest.$ac_objext && ac_ext=$ac_objext && boost_use_source=false &&
|
|---|
| 1071 | _AS_ECHO_LOG([re-using the existing conftest.$ac_objext])
|
|---|
| 1072 | AS_IF([_AC_DO_STDERR($ac_link) && {
|
|---|
| 1073 | test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
|
|---|
| 1074 | test ! -s conftest.err
|
|---|
| 1075 | } && test -s conftest$ac_exeext && {
|
|---|
| 1076 | test "$cross_compiling" = yes ||
|
|---|
| 1077 | $as_executable_p conftest$ac_exeext
|
|---|
| 1078 | dnl FIXME: use AS_TEST_X instead when 2.61 is widespread enough.
|
|---|
| 1079 | }],
|
|---|
| 1080 | [$2],
|
|---|
| 1081 | [if $boost_use_source; then
|
|---|
| 1082 | _AC_MSG_LOG_CONFTEST
|
|---|
| 1083 | fi
|
|---|
| 1084 | $3])
|
|---|
| 1085 | ac_objext=$boost_save_ac_objext
|
|---|
| 1086 | ac_ext=$boost_save_ac_ext
|
|---|
| 1087 | dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
|
|---|
| 1088 | dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
|
|---|
| 1089 | dnl as it would interfere with the next link command.
|
|---|
| 1090 | rm -f core conftest.err conftest_ipa8_conftest.oo \
|
|---|
| 1091 | conftest$ac_exeext m4_ifval([$1], [conftest.$ac_ext])[]dnl
|
|---|
| 1092 | ])# _BOOST_AC_LINK_IFELSE
|
|---|
| 1093 |
|
|---|
| 1094 | # Local Variables:
|
|---|
| 1095 | # mode: autoconf
|
|---|
| 1096 | # End:
|
|---|
