Context Navigation

source: configure.ac@ f01bb3

Visit:

Candidate_v1.7.0 stable

Last change on this file since f01bb3 was f01bb3, checked in by Frederik Heber <frederik.heber@…>, 5 years ago

CppUnit detected by pkg-config as fallback.

ubunntu 18.04 no longer has cppunit-config but relies on pkg-config to detect compilation flags.

Property mode set to 100644

File size: 20.7 KB

Line
1	# -- Autoconf --
2	# Process this file with autoconf to produce a configure script.
3
4	AC_PREREQ(2.59)
5	AC_INIT(MoleCuilder, 1.6.1, [bug@molecuilder.de], [molecuilder], [http://www.molecuilder.de/])
6	AC_CONFIG_AUX_DIR([build-aux])
7	AC_CONFIG_SRCDIR([src/builder.cpp])
8	AC_CONFIG_HEADER([config.h libmolecuilder_config.h])
9	AC_CONFIG_MACRO_DIR([m4])
10	AC_CONFIG_SUBDIRS([ThirdParty/LinearAlgebra])
11	AC_CONFIG_SUBDIRS([ThirdParty/mpqc_open])
12
13	# parallel-tests: use parallel test druver
14	# color-tests: us coloring to indicate success/failure when available
15	# tar-pax: use newer tar implementation with longer filename (>99 chars)
16	AM_INIT_AUTOMAKE([dist-bzip2 1.5 parallel-tests color-tests tar-pax subdir-objects])
17
18	# Checks for programs.
19	AC_PROG_CXX
20	AC_PROG_INSTALL
21
22	# check for cppunit (taken from svn.apache.org/../xmlbeanscxx)
23	AM_PATH_CPPUNIT(1.9.6,
24	[AM_CONDITIONAL([CPPUNIT], [true])],
25	[
26	PKG_CHECK_MODULES(CPPUNIT, [cppunit >= 1.9.6],
27	[AM_CONDITIONAL([CPPUNIT], [true])],
28	[AM_CONDITIONAL([CPPUNIT], [false])]
29	)
30	]
31	)
32	AM_CONDITIONAL(CONDCPPUNIT, test "$CPPUNIT_LIBS")
33
34	dnl Check if we have enable python
35	# python module-
36	AC_MSG_CHECKING(whether to enable python module)
37	AC_ARG_ENABLE(
38	[python],
39	AS_HELP_STRING([--enable-python],[turn on python module [default=yes]]),
40	enable_python=$enableval,
41	enable_python="yes")
42	AC_MSG_RESULT($enable_python)
43	AS_IF([test x"$enable_python" != x"no"],[
44	# Python (for boost::python)
45	AM_PATH_PYTHON([2.2])
46	AC_DEFINE(HAVE_PYTHON,1, ["Build python module and scripts."])
47	])
48	python_version_major=`echo $PYTHON_VERSION \| sed -e "s#$[0-9]$\..*#\1#"`
49	AM_CONDITIONAL([CONDPYTHON], [test x"$enable_python" != x"no"])
50	AS_IF([test x"$python_version_major" = x"2"],[
51	AC_DEFINE(HAVE_PYTHON2, 1, ["using python version 2"])
52	],[test x"$python_version_major" = x"3"],[
53	AC_DEFINE(HAVE_PYTHON3, 1, ["using python version 3"])
54	])
55	AC_SUBST(HAVE_PYTHON)
56
57	dnl Check whether no extra thread for ActionQueue shall be used
58	AC_MSG_CHECKING(whether to enable ActionQueue's run thread)
59	AC_ARG_ENABLE(
60	[action_thread],
61	AS_HELP_STRING([--enable-action-thread],[turn on extra run thread for ActionQueue [default=yes]]),
62	enable_action_thread=$enableval,
63	enable_action_thread="no"
64	)
65	AC_MSG_RESULT($enable_action_thread)
66	AS_IF([test x"$enable_action_thread" != x"no"],[
67	AC_DEFINE(HAVE_ACTION_THREAD,1, ["Have extra run thread for ActionQueue."])
68	])
69	AM_CONDITIONAL([CONDACTIONTHREAD], [test x"$enable_action_thread" != x"no"])
70	AC_SUBST(HAVE_ACTION_THREAD)
71
72	dnl Check if we have enable qtgui
73	# Qt programs
74	AC_MSG_CHECKING(whether to enable Qt-based GUI)
75	AC_ARG_ENABLE(
76	[qtgui],
77	AS_HELP_STRING([--enable-qtgui],[turn on Qt GUI compilation [default=yes]]),
78	enable_qtgui=$enableval,
79	enable_qtgui="yes")
80	AC_MSG_RESULT($enable_qtgui)
81	AS_IF([test x"$enable_qtgui" != x"no"],[
82	AC_ARG_WITH(
83	[Qt-bin],
84	[AS_HELP_STRING([--with-Qt-bin], [give path to Qt binaries])],
85	[have_qtgui_path=$withval],
86	have_qtgui_path="")
87	AS_IF([test x"$have_qtgui_path" != x""],[
88	AC_PATH_PROGS([QT_MOC],
89	[moc-qt4 moc],
90	[AC_MSG_ERROR(["Qts moc not found, please use --with-Qt-bin."])],
91	[$have_qtgui_path]
92	)
93	AC_PATH_PROGS([QT_RCC],
94	[rcc-qt4 rcc],
95	[AC_MSG_ERROR(["Qts rcc not found, please use --with-Qt-bin."])],
96	[$have_qtgui_path]
97	)
98	AC_PATH_PROGS([QT_UIC],
99	[uic-qt4 uic],
100	[AC_MSG_ERROR(["Qts uic not found, please use --with-Qt-bin."])],
101	[$have_qtgui_path]
102	)
103	],[
104	AC_PATH_PROGS([QT_MOC],
105	[moc-qt4 moc],
106	[AC_MSG_ERROR(["Qts moc not found, please use --with-Qt-bin."])]
107	)
108	AC_PATH_PROGS([QT_RCC],
109	[rcc-qt4 rcc],
110	[AC_MSG_ERROR(["Qts rcc not found, please use --with-Qt-bin."])]
111	)
112	AC_PATH_PROGS([QT_UIC],
113	[uic-qt4 uic],
114	[AC_MSG_ERROR(["Qts uic not found, please use --with-Qt-bin."])]
115	)
116	])
117	PKG_CHECK_MODULES([QT], [QtCore QtGui Qt3D], [
118	:
119	])
120	AC_SUBST([QT_CFLAGS])
121	AC_SUBST([QT_LIBS])
122	AC_DEFINE(HAVE_QTGUI,1, ["Build Qt-based GUI"])
123	])
124	AM_CONDITIONAL([CONDQTGUI], [test x"$enable_qtgui" != x"no"])
125	AC_SUBST(HAVE_QTGUI)
126
127	dnl Check whether qtgui captures log or not
128	AC_MSG_CHECKING(whether to capture stdout in qtgui)
129	AC_ARG_ENABLE(
130	[qtgui_capture_log],
131	AS_HELP_STRING([--enable-qtgui-capture-log],[turn on capturing of log inside qtgui [default=yes]]),
132	enable_qtgui_capture_log=$enableval,
133	enable_qtgui_capture_log="yes"
134	)
135	AC_MSG_RESULT($enable_qtgui_capture_log)
136	AS_IF([test x"$enable_qtgui_capture_log" != x"no"],[
137	AC_DEFINE(QT_CAPTURES_LOG,1, ["Have QtGui capture the stdout."])
138	])
139	AC_SUBST(QT_CAPTURES_LOG)
140
141
142	# check additionally for QWT to enable plotting of potentials
143	AC_MSG_CHECKING(whether to enable Qwt-based plotting)
144	#enable_qwt=yes
145	AC_ARG_ENABLE(
146	[qwt],
147	AS_HELP_STRING([--enable-qwt],[turn on Qwt compilation [default=yes]]),
148	enable_qwt=$enableval,
149	enable_qwt="yes")
150	AC_MSG_RESULT($enable_qwt)
151	AS_IF([test x"$enable_qwt" != x"no"],[
152	MOL_AC_HAVE_QWT_IFELSE(
153	[
154	enable_qwt=yes
155	AC_DEFINE(HAVE_QWT,1, ["Build Qwt-based plotting"])
156	],
157	[
158	enable_qwt=no
159	AC_MSG_WARN([Qwt not found, disabling plotting in QtUI.])
160	]
161	)
162	])
163	AM_CONDITIONAL([CONDQWT], [test x"$enable_qwt" != x"no"])
164	AC_SUBST(HAVE_QWT)
165
166	# use doxygen
167	DX_HTML_FEATURE(ON)
168	DX_PS_FEATURE(OFF)
169	DX_PDF_FEATURE(OFF)
170	DX_INIT_DOXYGEN(MoleCuilder, Doxyfile, ${docdir})
171
172	# use docbook
173	AX_CHECK_DOCBOOK
174
175	# use libtool
176	LT_INIT([static])
177	AC_SUBST([LIBTOOL_DEPS])
178
179	# Define these substitions here to keep all version information in one place.
180	# For information on how to properly maintain the library version information,
181	# refer to the libtool manual, section "Updating library version information":
182	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
183	AC_SUBST([MOLECUILDER_SO_VERSION], [18:0:1])
184	AC_SUBST([MOLECUILDER_API_VERSION], [1.6.1])
185
186	dnl this macro is used to get the arguments supplied
187	dnl to the configure script (./configure --enable-debug)
188	dnl Check if we have enable debug support.
189	AC_MSG_CHECKING(whether to enable debugging)
190	have_debug="no"
191	AC_ARG_ENABLE(
192	[debug],
193	AS_HELP_STRING([--enable-debug],[turn on debugging [default=no]]),
194	enable_debug=$enableval,
195	enable_debug="no")
196	AC_MSG_RESULT($enable_debug)
197	AS_IF([test x"$enable_debug" = x"yes"],[
198	AC_DEFINE(MEMDEBUG,1, ["Use memory debugger."])
199	AC_DEFINE(HAVE_DEBUG,1, ["Use debug setting to compile code."])
200	have_debug="yes"
201	],[
202	AS_IF([test x"$enable_debug" = x"full"],[
203	AC_DEFINE(MEMDEBUG,1, ["Use memory debugger."])
204	AC_DEFINE(LOG_OBSERVER,1, ["Use observer log."])
205	AC_DEFINE(HAVE_DEBUG,2, ["Use debug setting to compile code."])
206	dnl AC_DEFINE(QT_DEBUG,, ["Enable Qt debug messages."])
207	have_debug="full"
208	],[
209	AC_DEFINE(NDEBUG,1, ["Don't compile in debugging code."])
210	AC_DEFINE(HAVE_DEBUG,0, ["Use debug setting to compile code."])
211	AC_DEFINE(QT_NO_DEBUG_OUTPUT,, ["Disable Qt debug messages."])
212	have_debug="no"
213	])
214	])
215	AC_SUBST(HAVE_DEBUG)
216
217	dnl this macro is used to get the arguments supplied
218	dnl to the configure script (./configure --enable-debug)
219	dnl Check if we have enable debug support.
220	AC_MSG_CHECKING(whether to enable internal caching/lazy evaluation)
221	AC_ARG_ENABLE(
222	[cache],
223	AS_HELP_STRING([--enable-cache],[turn on internal lazy evaluation [default=yes]]),
224	enable_cache=$enableval,
225	enable_cache="yes")
226	AC_MSG_RESULT($enable_cache)
227	AS_IF([test x"$enable_cache" != x"no"],[
228	AC_DEFINE(HAVE_CACHE,1, ["cache variables to speed up the code."])
229	],[
230	AC_DEFINE(NO_CACHING,1, ["Don't use caching code."])
231	AC_DEFINE(HAVE_CACHE,0, ["cache variables to speed up the code."])
232	])
233	AC_SUBST(HAVE_CACHE)
234
235	# Checks for libraries.
236	AC_CHECK_LIB(m, sqrt, , AC_MSG_ERROR([compatible libc math library not found]))
237
238	# Pthreads
239	ACX_PTHREAD()
240
241	# Boost
242	BOOST_REQUIRE([1.40])
243
244	# Boost headers only
245	BOOST_ANY
246	BOOST_ARRAY
247	BOOST_BIMAP
248	BOOST_BIND
249	BOOST_CAST
250	BOOST_CONVERSION
251	BOOST_EXCEPTION
252	BOOST_FOREACH
253	BOOST_FUNCTION
254	BOOST_FUSION
255	BOOST_GRAPH
256	BOOST_ITERATOR
257	BOOST_MULTIARRAY
258	BOOST_MULTIINDEXCONTAINER
259	BOOST_MPL
260	BOOST_PREPROCESSOR
261	BOOST_RANDOM
262	BOOST_SMART_PTR
263	BOOST_STRING_ALGO
264	BOOST_TOKENIZER
265
266	# Boost headers with libraries
267	BOOST_FILESYSTEM
268	BOOST_IOSTREAMS
269	BOOST_PROGRAM_OPTIONS
270	AS_IF([test x"$enable_python" != x"no"], [BOOST_PYTHON])
271	BOOST_SERIALIZATION
272	BOOST_THREADS
273
274
275	# CodePatterns library (requiring UnobservedIterator)
276	compile_codepatterns="no"
277	AM_PATH_CODEPATTERNS([1.3.2], $have_debug,,[
278	# compile from ThirdParty
279	AC_CONFIG_SUBDIRS([ThirdParty/CodePatterns])
280	compile_codepatterns="yes"
281	[CodePatterns_LDFLAGS='-L$(top_builddir)/ThirdParty/CodePatterns/src']
282	[CodePatterns_CFLAGS='-I$(top_srcdir)/ThirdParty/CodePatterns/src']
283	AS_IF([test x"$enable_debug" != x"no"], [
284	[CodePatterns_LIBS='-lcodepatterns-debug']
285	],[
286	[CodePatterns_LIBS='-lcodepatterns']
287	])
288	AC_SUBST(CodePatterns_LDFLAGS)
289	AC_SUBST(CodePatterns_CFLAGS)
290	AC_SUBST(CodePatterns_LIBS)
291	#AC_MSG_ERROR([Missing CodePatterns library, please specify PKG_CONFIG_PATH or use --with-codepatterns...])
292	])
293	AC_MSG_CHECKING(whether to compile codepatterns)
294	AC_MSG_RESULT($compile_codepatterns)
295	AM_CONDITIONAL([COND_COMPILE_CODEPATTERNS], [test x"$compile_codepatterns" = x"yes"])
296
297	# JobMarket library (needs boost/archive/iserializer.hpp before MemDebug.hpp)
298	AC_MSG_CHECKING(whether to enable jobmarket)
299	AC_ARG_ENABLE(
300	[jobmarket],
301	AS_HELP_STRING([--enable-jobmarket],[turn on JobMarket feature [default=yes]]),
302	enable_jobmarket=$enableval,
303	enable_jobmarket="yes")
304	AC_MSG_RESULT($enable_jobmarket)
305	compile_jobmarket="no"
306	AC_MSG_CHECKING(whether to compile jobmarket)
307	AS_IF([test x"$enable_jobmarket" != x"no"],[
308	# the following is only required if we use JobMarket
309	BOOST_ASIO
310	AC_DEFINE(HAVE_JOBMARKET,1, ["use JobMarket to calculate fragment jobs."])
311	# JobMarket library (needs SystemCommandJob with suffix)
312	AM_PATH_JOBMARKET([1.1.6], $have_debug,
313	,[
314	AC_CONFIG_SUBDIRS([ThirdParty/JobMarket])
315	compile_jobmarket="yes"
316	[JobMarket_CFLAGS='-I$(top_srcdir)/ThirdParty/JobMarket/src']
317	[JobMarket_LDFLAGS='-L$(top_builddir)/ThirdParty/JobMarket/src/JobMarket']
318	[JobMarket_LIBS='-lJobMarket']
319	[JobMarket_Controller_LIBS='-lJobMarketController']
320	[JobMarket_Server_LIBS='-lJobMarketServer']
321	[JobMarket_PoolWorker_LIBS='-lJobMarketPoolWorker']
322	AC_SUBST(JobMarket_CFLAGS)
323	AC_SUBST(JobMarket_LDFLAGS)
324	AC_SUBST(JobMarket_LIBS)
325	AC_SUBST(JobMarket_Controller_LIBS)
326	AC_SUBST(JobMarket_Server_LIBS)
327	AC_SUBST(JobMarket_PoolWorker_LIBS)
328	])
329	]
330	AC_MSG_RESULT($compile_jobmarket)
331	#[
332	# AC_DEFINE(HAVE_JOBMARKET,0, ["use JobMarket to calculate fragment jobs."])
333	#]
334	)
335	AC_SUBST(HAVE_JOBMARKET)
336	AM_CONDITIONAL([COND_COMPILE_JOBMARKET], [test x"$compile_jobmarket" = x"yes"])
337	AM_CONDITIONAL([CONDJOBMARKET], [test x"$enable_jobmarket" = x"yes"])
338
339	# VMG library
340	AC_MSG_CHECKING(whether to compile in long-range support via vmg)
341	AC_ARG_ENABLE(
342	[vmg],
343	[AS_HELP_STRING([--enable-vmg], [turn on long-range potential calculation via VMG [default=no]])],
344	[enable_vmg=$enableval],
345	enable_vmg="no")
346	AC_MSG_RESULT($enable_vmg)
347	compile_vmg="no"
348	AC_MSG_CHECKING(whether to compile vmg library)
349	AS_IF([test x"$enable_vmg" != x"no"],[
350	PKG_CHECK_MODULES(VMG, VMG >= 0.1, [enable_vmg="yes"], [enable_vmg="no"])
351	AS_IF([test x"$enable_vmg" = x"no"],[
352	AC_CONFIG_SUBDIRS([ThirdParty/vmg])
353	compile_vmg="yes"
354	enable_vmg="yes"
355	[VMG_CFLAGS='-I$(top_srcdir)/ThirdParty/vmg/src']
356	[VMG_LDFLAGS='-L$(top_builddir)/ThirdParty/vmg/src']
357	[VMG_LIBS='-lvmg']
358	])
359	AC_SUBST(VMG_CFLAGS)
360	AC_SUBST(VMG_LDFLAGS)
361	AC_SUBST(VMG_LIBS)
362	AC_DEFINE(HAVE_VMG,1, ["use VMG to calculate long-range contributions."])
363
364	# check whether to use mpi
365	AC_ARG_WITH(
366	[vmg-mpi],
367	[AS_HELP_STRING([--with-vmg-mpi], [whether to use MPI for communication in VMGJobs])],
368	[with_vmg_mpi=yes],
369	[with_vmg_mpi=no])
370	AS_IF(
371	[test "x$with_vmg_mpi" != xno],
372	[
373	AC_LANG_SAVE
374	AC_LANG_CPLUSPLUS
375	LX_FIND_MPI
376	AC_LANG_RESTORE
377	AS_IF([test "x$have_CXX_mpi" = xyes],[
378	AC_DEFINE([MPICH_SKIP_MPICXX], [1], [Skip C++ bindings])
379	AC_DEFINE([OMPI_SKIP_MPICXX], [1], [Skip C++ bindings])
380	AC_DEFINE([MPI_NO_CPPBIND], [1], [Skip C++ bindings])
381	AC_DEFINE([_MPICC_H], [1], [Skip C++ bindings])
382	AC_DEFINE([MPIBULL_SKIP_MPICXX], [1], [Skip C++ bindings])
383	#ac_configure_args="$ac_configure_args --with-mpi-thread=single --with-default-parallel=mpi --with-include=\"$MPI_CXXFLAGS\" --with-libs=\"$MPI_CXXLDFLAGS\""
384	ac_configure_args="$ac_configure_args --with-default-parallel=none"
385	])
386	],
387	[])
388	])
389	AC_MSG_RESULT($compile_vmg)
390	AM_CONDITIONAL([CONDVMG], [test x"$enable_vmg" = x"yes"])
391	AM_CONDITIONAL([CONDVMGMPI], [test x"$have_CXX_mpi" = x"yes"])
392	AM_CONDITIONAL([COND_COMPILE_VMG], [test x"$compile_vmg" = x"yes"])
393
394
395	# Check for Levenberg-Marquardt implementation
396	AC_MSG_CHECKING(whether to enable function fitting via levmar)
397	AC_ARG_ENABLE(
398	[levmar],
399	AS_HELP_STRING([--enable-levmar],[turn on LevMar feature [default=no]]),
400	enable_levmar=$enableval,
401	enable_levmar="no")
402	AC_MSG_RESULT($enable_levmar)
403	# don't use AS_IF here as it expands (and tests) AC_F77_FUN even if levmar
404	# is disabled.
405	compile_levmar="no"
406	AS_IF([test x"$enable_levmar" = xyes],[
407	AC_MSG_CHECKING(for levmar presence via given path )
408	AC_ARG_WITH(
409	[levmar],
410	[AS_HELP_STRING([--with-levmar], [give path to LevMar package])],
411	[have_levmar_path=$withval
412	enable_levmar=yes],
413	[
414	enable_levmar=no
415	])
416	AC_MSG_RESULT($enable_levmar)
417	AS_IF([test -n "$have_levmar_path"],[
418	LEVMAR_CPPFLAGS="-I${have_levmar_path}/include"
419	LEVMAR_LDFLAGS="-L${have_levmar_path}/lib"
420	LEVMAR_LIBS="-llevmar"],
421	[PKG_CHECK_MODULES([LEVMAR],[levmar],[enable_levmar=yes],[enable_levmar=no])
422	])
423	],[enable_levmar=no]
424	)
425	if test x"$enable_levmar" = xyes; then
426	AX_LAPACK([enable_levmar=yes],
427	[enable_levmar=no
428	AC_MSG_WARN(["Missing LAPACK, disabling off levmar"])
429	]
430	)
431	else
432	AC_CONFIG_SUBDIRS([ThirdParty/levmar])
433	compile_levmar="yes"
434	enable_levmar="yes"
435	LEVMAR_CPPFLAGS='-I$(top_srcdir)/ThirdParty/levmar/src'
436	LEVMAR_LDFLAGS='-L$(top_builddir)/ThirdParty/levmar/src'
437	LEVMAR_LIBS='-llevmar'
438	fi
439	AC_MSG_CHECKING(for levmar usability)
440	AS_IF([test x"$enable_levmar" = xyes],[
441	AC_SUBST(LEVMAR_CPPFLAGS)
442	AC_SUBST(LEVMAR_LDFLAGS)
443	AC_SUBST(LEVMAR_LIBS)
444	AC_DEFINE(HAVE_LEVMAR,1, ["use levmar for non-linear minimisation/potential fitting."])])
445	AC_MSG_RESULT($enable_levmar)
446	AM_CONDITIONAL([CONDLEVMAR], [test x"$enable_levmar" = x"yes"])
447	AM_CONDITIONAL([COND_COMPILE_LEVMAR], [test x"$compile_levmar" = x"yes"])
448
449	# Checks for header files.
450	AC_HEADER_STDC
451	AC_CHECK_HEADERS([sys/time.h])
452	AC_HEADER_STDBOOL
453
454	AC_FUNC_MALLOC
455	AC_FUNC_REALLOC
456	AC_CHECK_FUNCS([floor pow sqrt strchr])
457
458	# Checks for typedefs, structures, and compiler characteristics.
459	AC_C_CONST
460	AC_C_INLINE
461	AC_C_RESTRICT
462	AC_TYPE_SIZE_T
463
464	# Checks for library functions.
465	# check for GNU Scientific Library
466	AC_CHECK_HEADERS([gsl/gsl_blas.h])
467	AC_SEARCH_LIBS(dnrm2, gslblas gslcblas goto blas cblas)
468	AC_SEARCH_LIBS(cblas_dnrm2, gslblas gslcblas blas cblas)
469	AC_SEARCH_LIBS(gsl_blas_dnrm2,, gsl)
470	#AC_CHECK_LIB(gsl, gsl_blas_dnrm2, , [AC_MSG_ERROR(["No working BLAS found for GSL, stopping."])])
471	AC_CHECK_LIB(gsl, main)
472
473	# use CppUnit TestRunner or not
474	AC_MSG_CHECKING(whether to enable ECut TestRunnerClient)
475	AC_ARG_ENABLE(
476	[ecut],
477	AS_HELP_STRING([--enable-ecut],[Use ECut TestRunnerClient [default=no]]),
478	enable_ecut=$disableval,
479	enable_ecut="no")
480	AC_MSG_RESULT($enable_ecut)
481	AS_IF([test x"$enable_ecut" = x"yes"],[
482	AC_DEFINE(HAVE_ECUT,1, ["Use ECut TestRunnerClient instead of our own."])
483	AC_SUBST(HAVE_ECUT)
484	])
485	AM_CONDITIONAL([CONDECUT], [test x"$enable_ecut" = x"yes"])
486
487	# with valgrinding testsuite or not
488	AC_MSG_CHECKING(whether to enable valgrind memory checking in testsuite)
489	AC_ARG_ENABLE(
490	[valgrind],
491	AS_HELP_STRING([--enable-valgrind],[Use Valgrind on the testsuite [default=no]]),
492	enable_valgrind=$enableval,
493	enable_valgrind="no")
494	AC_MSG_RESULT($enable_valgrind)
495	AS_IF([test x"$enable_valgrind" = x"yes"], [
496	AC_CHECK_HEADER([valgrind/valgrind.h],
497	[
498	# check header
499	AC_DEFINE(HAVE_VALGRIND_TESTSUITE,1, ["Use Valgrind to check the testsuite."])
500	# check path
501	AC_PATH_PROG(VALGRIND, [valgrind], [/bin/false])
502	# set variables
503	AC_SUBST(HAVE_VALGRIND_TESTSUITE)
504	AC_SUBST(VALGRIND)
505	],
506	[
507	AC_MSG_ERROR(["Valgrind support requested but headers not available."])
508	]
509	)
510	])
511
512	# Check for "extern inline", using a modified version
513	# of the test for AC_C_INLINE from acspecific.mt
514	AC_CACHE_CHECK([for extern inline], ac_cv_c_extern_inline,
515	[ac_cv_c_extern_inline=no
516	AC_TRY_COMPILE([extern $ac_cv_c_inline double foo(double x);
517	extern $ac_cv_c_inline double foo(double x) { return x+1.0; };
518	double foo (double x) { return x + 1.0; };],
519	[ foo(1.0) ],
520	[ac_cv_c_extern_inline="yes"])
521	])
522
523	if test "$ac_cv_c_inline" != no ; then
524	AC_DEFINE(HAVE_INLINE,1, ["May use inline routines"])
525	AC_SUBST(HAVE_INLINE)
526	fi
527
528	#AC_MSG_NOTICE(["CFLAGS: $CFLAGS, CXXFLAGS: $CXXFLAGS, LDFLAGS: $LDFLAGS, CC: $CC, CXX:, $CXX, MPICC: $MPICC, MPILIBS: $MPILIBS, LIBS: $LIBS"])
529
530	# test suite
531
532	AC_CONFIG_FILES([
533	tests/Makefile])
534
535	AC_CONFIG_TESTDIR(tests/Calculations)
536	AC_CONFIG_FILES([
537	tests/Calculations/atlocal
538	tests/Calculations/Makefile])
539	AC_CONFIG_FILES([tests/Calculations/molecuilder], [chmod +x tests/Calculations/molecuilder])
540	AC_CONFIG_FILES([tests/Calculations/molecuilder_poolworker], [chmod +x tests/Calculations/molecuilder_poolworker])
541
542	AC_CONFIG_TESTDIR(tests/CodeChecks)
543	AC_CONFIG_FILES([
544	tests/CodeChecks/atlocal
545	tests/CodeChecks/Makefile])
546
547	AC_CONFIG_TESTDIR(tests/Fragmentations)
548	AC_CONFIG_FILES([
549	tests/Fragmentations/atlocal
550	tests/Fragmentations/Makefile])
551	AC_CONFIG_FILES([tests/Fragmentations/molecuilder], [chmod +x tests/Fragmentations/molecuilder])
552
553	AC_CONFIG_TESTDIR(tests/GuiChecks)
554	AC_CONFIG_FILES([
555	tests/GuiChecks/atlocal
556	tests/GuiChecks/Makefile])
557	AC_CONFIG_FILES([tests/GuiChecks/molecuilder], [chmod +x tests/GuiChecks/molecuilder])
558	AC_CONFIG_FILES([tests/GuiChecks/molecuilderguitest], [chmod +x tests/GuiChecks/molecuilderguitest])
559	AC_CONFIG_FILES([tests/GuiChecks/adjacencymatcher], [chmod +x tests/GuiChecks/adjacencymatcher])
560	AC_CONFIG_FILES([tests/GuiChecks/difffragmentresultcontainer], [chmod +x tests/GuiChecks/difffragmentresultcontainer])
561	AC_CONFIG_FILES([tests/GuiChecks/trianglematcher], [chmod +x tests/GuiChecks/trianglematcher])
562
563	AC_CONFIG_TESTDIR(tests/JobMarket)
564	AC_CONFIG_FILES([
565	tests/JobMarket/atlocal
566	tests/JobMarket/Makefile])
567	AC_CONFIG_FILES([tests/JobMarket/molecuilder], [chmod +x tests/JobMarket/molecuilder])
568
569	AC_CONFIG_TESTDIR(tests/integration)
570	AC_CONFIG_FILES([
571	tests/integration/atlocal
572	tests/integration/Makefile])
573	AC_CONFIG_FILES([tests/integration/molecuilder], [chmod +x tests/integration/molecuilder])
574	AC_CONFIG_FILES([tests/integration/molecuilder_poolworker], [chmod +x tests/integration/molecuilder_poolworker])
575
576	AC_CONFIG_TESTDIR(tests/regression)
577	AC_CONFIG_FILES([
578	tests/regression/atlocal
579	tests/regression/Makefile])
580	AC_CONFIG_FILES([tests/regression/molecuilder], [chmod +x tests/regression/molecuilder])
581	AC_CONFIG_FILES([tests/regression/adjacencymatcher], [chmod +x tests/regression/adjacencymatcher])
582	AC_CONFIG_FILES([tests/regression/difffragmentresultcontainer], [chmod +x tests/regression/difffragmentresultcontainer])
583	AC_CONFIG_FILES([tests/regression/trianglematcher], [chmod +x tests/regression/trianglematcher])
584	AC_CONFIG_FILES([tests/regression/runpython], [chmod +x tests/regression/runpython])
585
586	AC_CONFIG_TESTDIR(tests/Tesselations)
587	AC_CONFIG_FILES([
588	tests/Tesselations/atlocal
589	tests/Tesselations/Makefile])
590	AC_CONFIG_FILES([tests/Tesselations/molecuilder], [chmod +x tests/Tesselations/molecuilder])
591	AC_CONFIG_FILES([tests/Tesselations/trianglematcher], [chmod +x tests/Tesselations/trianglematcher])
592
593	AC_CONFIG_TESTDIR(tests/Examples)
594	AC_CONFIG_FILES([
595	tests/Examples/atlocal
596	tests/Examples/Makefile])
597	AC_CONFIG_FILES([tests/Examples/molecuilder], [chmod +x tests/Examples/molecuilder])
598	AC_CONFIG_FILES([tests/Examples/molecuilder_poolworker], [chmod +x tests/Examples/molecuilder_poolworker])
599
600	AC_CONFIG_FILES([
601	doc/molecuilder.xml])
602	AC_CONFIG_FILES([
603	doc/userguide/catalog.xml:doc/userguide/catalog.xml.in])
604	AC_CONFIG_FILES([
605	MoleCuilder.pc:MoleCuilder.pc.in])
606	AC_CONFIG_FILES([
607	doc/Makefile
608	doc/userguide/Makefile
609	])
610	AC_CONFIG_FILES([
611	Makefile
612	python/Makefile
613	src/Makefile
614	src/Bond/AdjacencyMatcher/Makefile
615	src/Tesselation/TriangleMatcher/Makefile
616	ThirdParty/Makefile
617	data/icons/Makefile
618	utils/Makefile
619	])
620	AC_CONFIG_FILES([
621	src/unittests/Makefile
622	])
623
624	# produce python scripts and tests only when python's present
625	AC_CONFIG_TESTDIR([tests/Python])
626	AC_CONFIG_FILES([tests/Python/atlocal])
627	AM_COND_IF([CONDPYTHON],[
628	AC_CONFIG_FILES([utils/Python/boxmaker.py:utils/Python/boxmaker.py.in], [chmod +x utils/Python/boxmaker.py])
629	AC_CONFIG_FILES([utils/Python/python_wrapper:utils/Python/python_wrapper.in], [chmod +x utils/Python/python_wrapper])
630	AC_CONFIG_FILES([tests/Python/run], [chmod +x tests/Python/run])
631	])
632	AC_CONFIG_FILES([tests/Python/Makefile])
633
634	AC_OUTPUT

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

Original Format